Dead simple example of using Lwt_engine to read files

dead_simple_read_files_in_lwt.ml

let string_of_buffer buffer = Buffer.to_bytes buffer |> Bytes.unsafe_to_string

let read_file ?(perm = 0o777) filename =
  let promise, resolver = Lwt.task () in

  let fd = Unix.openfile filename [ O_RDONLY ] perm in

  let buffer = Buffer.create 1024 in
  let chunk = Bytes.create 1024 in
  let chunk_length = Bytes.length chunk in

  let dispose ev =
    Lwt_engine.stop_event ev;
    Unix.close fd
  in

  let ev =
    Lwt_engine.on_readable fd @@ fun ev ->
    let bytes_read = Unix.read fd chunk 0 chunk_length in

    Buffer.add_subbytes buffer chunk 0 bytes_read;

    if bytes_read = 0 then begin
      dispose ev;
      Lwt.wakeup resolver (string_of_buffer buffer)
    end
  in

  Lwt.on_cancel promise (fun () -> dispose ev);

  promise

let () =
  let read_and_print = Fun.compose (Lwt.Infix.( =<< ) Lwt_io.printl) read_file in

  Lwt_main.run begin
    Sys.argv |> Array.to_list |> List.tl |> Lwt_list.iter_p read_and_print
  end