OpenSCAD Source Code: Vacuum Tube LED Plate Cap

Vacuum Tube Lights.scad

// Vacuum Tube LED Lights
// Ed Nisley KE4ZNU January 2016

Layout = "Cap";						// Show Build Cap Box Octal Noval Mini7

Section = true;							// cross-section the object

//- Extrusion parameters must match reality!

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

Protrusion = 0.1;			// make holes end cleanly

inch = 25.4;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

//----------------------
// Dimensions
// https://en.wikipedia.org/wiki/Tube_socket#Summary_of_Base_Details

T_NAME = 0;
T_NUMPINS = 1;											// Socket specifications
T_PINCIRC = 2;
T_PINDIA = 3;
T_SOCKDIA = 4;

TubeBase = [
	["Mini7", 8,  9.53, 1.016, 19.0],
	["Octal", 8, 17.45, 2.36,  33.0],
	["Noval",10, 11.89, 1.1016,20.5],
];

ID = 0;
OD = 1;
LENGTH = 2;

Pixel = [7.0,10.0,3.0];								// ID = contact patch, OD = PCB dia, LENGTH = overall thickness

//----------------------
// Useful routines

module PolyCyl(Dia,Height,ForceSides=0) {			// based on nophead's polyholes

  Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);

  FixDia = Dia / cos(180/Sides);

  cylinder(r=(FixDia + HoleWindage)/2,
		h=Height,
	$fn=Sides);
}

//----------------------
// Tube cap

CapTube = [4.0,3/16 * inch,10.0];						// brass tube for flying lead to cap LED

CapSize = [Pixel[ID],(Pixel[OD] + 3.0),(CapTube[OD] + 2*Pixel[LENGTH])];

CapSides = 6*4;

module Cap() {
	
	difference() {
		union() {
			cylinder(d=CapSize[OD],h=(CapSize[LENGTH]),$fn=CapSides);		// main cap body
			translate([0,0,CapSize[LENGTH]])								// rounded top
				scale([1.0,1.0,0.65])
					sphere(d=CapSize[OD]/cos(180/CapSides),$fn=CapSides);	// cos() fixes slight undersize vs cylinder
			cylinder(d1=(CapSize[OD] + 2*3*ThreadWidth),d2=CapSize[OD],h=1.5*Pixel[LENGTH],$fn=CapSides);	// skirt
		}
		
		translate([0,0,-Protrusion])								// bore for wiring to LED
			PolyCyl(CapSize[ID],(CapSize[LENGTH] + 3*ThreadThick + Protrusion),CapSides);
			
		translate([0,0,-Protrusion])								// PCB recess with clearance for tube dome
			PolyCyl(Pixel[OD],(1.5*Pixel[LENGTH] + Protrusion),CapSides);
			
		translate([0,0,(1.5*Pixel[LENGTH] - Protrusion)])			// step + cone to retain PCB
			cylinder(d1=(Pixel[OD]/cos(180/CapSides)),d2=Pixel[ID],h=(Pixel[LENGTH] + Protrusion),$fn=CapSides);
			
		translate([0,0,(CapSize[LENGTH] - CapTube[OD]/(2*cos(180/8)))])	// hole for brass tube holding wire loom
			rotate([90,0,0]) rotate(180/8)
				PolyCyl(CapTube[OD],CapSize[OD],8);
	}
	
}



//----------------------
// Build it

if (Layout == "Cap") {
	if (Section)
		difference() {
			Cap();
			translate([-CapSize[OD],0,CapSize[LENGTH]])
				cube([2*CapSize[OD],2*CapSize[OD],3*CapSize[LENGTH]],center=true);
		}
	else
		Cap();
}

if (Layout == "Build") {
	Cap();
	Spigot();
}

More details on my blog at http://wp.me/poZKh-5z5