OpenSCAD source code: Brackets for shades over LED strips inside laser cutter

COB LED Shade brackets.scad

// Bracket for COB LED shade
// Ed Nisley KE4ZNU 2022-03-24

BaseLength = 20.0;

/* [Hidden] */

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

Protrusion = 0.1;     // make holes end cleanly

WebThick = 4*ThreadWidth;
BasePlate = [BaseLength,5*WebThick,WebThick];


//----------
// Create parts

module Bracket() {

  R = BaseLength/3;
  N = 36;

  union() {
    rotate([90,0,0])
      translate([0,0,-WebThick/2])
        linear_extrude(height=WebThick,convexity=2)
          difference() {
            intersection() {
              union () {
                square(2*R,center=false);
                translate([0,2*R])
                  rotate(180/N)
                    circle(r=R,$fn=N);
                translate([2*R,0])
                  rotate(180/N)
                    circle(r=R,$fn=N);
              }
              square(3*R,center=false);
            }
            translate([2*R*cos(180/N),2*R*cos(180/N)])
              rotate(180/N)
                circle(r=R,$fn=N);
          }
    rotate([0,-90,0])
      translate([0,-BasePlate.y/2,-BasePlate.z])
        cube(BasePlate,center=false);
    translate([0,-BasePlate.y/2,0])
      cube(BasePlate,center=false);
  }
}

//----------
// Build them

Bracket();

More details on my blog at https://wp.me/poZKh-aPg

The shades are at: https://gist.github.com/ednisley/0311239247282832abc55e07b26b75d8