PKGBUILD for vcvrack-git

PKGBUILD

# Maintainer: Popolon <popolon@popolon.org>
# Contributor: Fabio 'Lolix' Loli <lolix@disroot.org>
# Contributor: Miroslav Koškár
# Contributor: eggix <eggix@protonmail.com>

pkgname=vcvrack-git
pkgver=2.0.1.r0.g888fd661
pkgrel=1
pkgdesc="Open-source virtual Eurorack DAW"
url="https://github.com/VCVRack/Rack"
license=(BSD)
arch=(i686 x86_64)
depends=(glew glfw-x11 jansson libsamplerate curl libzip rtmidi rtaudio gtk3 jq)
makedepends=(git unzip wget cmake)
provides=(vcvrack)
conflicts=(vcvrack)
source=(
    "${pkgname%-git}::git+https://github.com/VCVRack/Rack.git"
    "${pkgname%-git}.desktop"
    "${pkgname%-git}.sh"
)
sha256sums=('SKIP'
            'a7aa48156543ca6d05def561b6708935d7fd284baff4412716ad7077fb221b6c'
            '6299d2de5b6c71db5c9e736095bbf141e4f0bc6eb90b4791aa384b3accd59bbd')

pkgver() {
    cd "${pkgname%-git}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "${pkgname%-git}"
    git submodule update --init --recursive
}

build() {
    cd "${pkgname%-git}"
    make dep
    local tag flags
    tag=$(git describe --tags --abbrev=0)
    export FLAGS=$(pkg-config --cflags-only-I glew glfw3 jansson samplerate libcurl libzip rtmidi rtaudio gtk+-3.0)
    make VERSION="${tag##v}"
}

package() {
    cd "${pkgname%-git}"
    install -vD -m755 "$srcdir/vcvrack.sh" "$pkgdir/usr/bin/vcvrack"
    install -vD -m644 -t "$pkgdir/usr/share/licenses/${pkgname%-git}" LICENSE*
    install -vD -m755 -t "$pkgdir/opt/${pkgname%-git}" Rack
    install -vd "$pkgdir/opt/${pkgname%-git}/plugins"
    install -vD -m644 -t "$pkgdir/usr/lib/" libRack.so

    install -D -m644 -t "$pkgdir/opt/${pkgname%-git}" Core.json template.vcv

    # headers (required for plugins)
    for _path in {app,dsp,engine,plugin,simd,ui,widget}; do
        install -vDm 644 "include/$_path/"* \
          -t "$pkgdir/usr/include/${pkgname%-git}/$_path/"
    done
    install -vDm 644 include/*.{h,hpp} -t "$pkgdir/usr/include/${pkgname%-git}/"
    install -vDm 644 dep/include/*.h -t "$pkgdir/usr/include/${pkgname%-git}/dep"
    # Makefile snippets required for plugins
    install -vDm 644 {arch,compile,dep,plugin}.mk -t "$pkgdir/usr/share/${pkgname%-git}"

    install -vD -m644 "$srcdir/vcvrack.desktop" -t "$pkgdir/usr/share/applications/"
    cp -dr --preserve=mode -t "$pkgdir/opt/${pkgname%-git}" res
}