Icon code for Apply, Reduce, and MovingAverage

ApplyReduceMovingAverage.icn

procedure Apply(f, L)
   local result, x
   result := []
   every x := !L do put(result, f(x)) | fail
   return result
end

procedure Reduce(f, L)
   if *L > 1 
      then return f( L[1], Reduce( f, L[2:0] ) )
      else return L[1]
end

$define MovingAverageFilterDepth 4
record moving_average(result, queue)

procedure MovingAverage(moving_average_record, latest)
   if type(moving_average_record) ~== "moving_average" then stop("MovingAverage: first argument must be a moving_average record but was ", type(moving_average_record))
   if type(moving_average_record.queue) ~== "list" then stop("MovingAverage: moving_average_record.queue must be a list")
   if *(moving_average_record.queue) = 0
      then every 1 to  MovingAverageFilterDepth do put(moving_average_record.queue, 0)
   pop(moving_average_record.queue)
   put(moving_average_record.queue, latest)
   return Reduce("+", moving_average_record.queue) / real(*moving_average_record.queue)
end

link trees, ximage

procedure main()
   local my_moving_average
   my_moving_average := moving_average(0, [])
   write(MovingAverage(my_moving_average, 1))
   write(MovingAverage(my_moving_average, 2))
   write(MovingAverage(my_moving_average, 4))
   write(MovingAverage(my_moving_average, 8))
   write(ximage(my_moving_average.queue))
   write(ximage(Apply(sqrt,my_moving_average.queue)))
   write(MovingAverage(my_moving_average, 0))
   write(MovingAverage(my_moving_average, 0))
   write(MovingAverage(my_moving_average, 0))
   write(ximage(Apply(sqrt,my_moving_average.queue)))
   write(MovingAverage(my_moving_average, 0))
end