Run this as `view (long (ls "."))`

TurtleLong.hs

{-# LANGUAGE OverloadedStrings #-}

module TurtleLong (long) where

import qualified Data.Text as T
import Prelude hiding (FilePath)
import Data.Time.Clock.POSIX

import Turtle



showFileType :: FileStatus -> Text
showFileType st
    | isBlockDevice st = "b"
    | isCharacterDevice st = "c"
    | isDirectory st = "d"
    | isNamedPipe st = "|"
    | isRegularFile st = "-"
    | isSocket st = "="
    | isSymbolicLink st = "s"
    | otherwise = "?"

showFileSize :: FileStatus -> Text
showFileSize st =
    T.justifyRight 10 ' ' $ T.pack (show (fileSize st))

showFileTime :: FileStatus -> Text
showFileTime st =
    format utc (posixSecondsToUTCTime (modificationTime st))

showFileStatus :: FileStatus -> Text
showFileStatus st =
    T.unwords [showFileType st, showFileSize st, showFileTime st]

-- TODO: quote spaces and newlines
showFileName :: FilePath -> Text
showFileName p =
    format fp p

showFilePathLong :: MonadIO io => FilePath -> io Line
showFilePathLong p = do
    st <- stat p
    return $ unsafeTextToLine $ T.unwords [showFileStatus st, showFileName p]

long :: Shell FilePath -> Shell Line
long ps = join $ fmap showFilePathLong ps