Filter / Params in Phoenix Controllers

episode_controller.ex

defmodule NeulandWeb.Admin.EpisodeController do
  use NeulandWeb, :controller

  alias Neuland.Repo
  alias Neuland.Directory
  alias Neuland.Directory.EpisodeParams

  @episodes_per_page 100

  def index(conn, %{"filter" => filter_params}) do
    changeset =
      EpisodeParams.changeset(%EpisodeParams{}, filter_params)
      |> Ecto.Changeset.put_change(:items_per_page, @episodes_per_page)

    if !changeset.valid? do
      render(conn, "error.html", %{errors: changeset.errors})
    else
      episodes =
        changeset
        |> EpisodeParams.to_params()
        |> Directory.list_episodes()
        |> Repo.preload(:podcast)

      render(conn, "index.html", episodes: episodes, filter: filter_params)
    end
  end

  def index(conn, _params) do
    episodes =
      Directory.list_episodes(%{"items_per_page" => @episodes_per_page})
      |> Repo.preload(:podcast)

    render(conn, "index.html", episodes: episodes, filter: %{})
  end

end

episode_params.ex

defmodule Neuland.Directory.EpisodeParams do
  use Ecto.Schema

  import Ecto.Changeset

  schema "" do
    field(:page, :integer, default: 1)
    field(:items_per_page, :integer, default: 10)
    field(:podcast_id, :integer)
    field(:slug, :string)
    field(:search, :string)
    field(:ids, :string)
    field(:br_domain_id, :string)
    field(:title, :string)
  end

  def changeset(episode_params, attrs) do
    episode_params
    |> cast(attrs, [
      :page,
      :items_per_page,
      :podcast_id,
      :slug,
      :search,
      :ids,
      :title,
      :br_domain_id
    ])
    |> validate_number(:page, greater_than: 0)
  end

  def to_params(changeset) do
    %{
      "page" => get_field(changeset, :page),
      "items_per_page" => get_field(changeset, :items_per_page),
      "podcast_id" => get_field(changeset, :podcast_id),
      "slug" => get_field(changeset, :slug),
      "search" => get_field(changeset, :search),
      "ids" => get_field(changeset, :ids),
      "title" => get_field(changeset, :title),
      "br_domain_id" => get_field(changeset, :br_domain_id)
    }
  end
end