Nomisma IDs created or edited by Andy Meadows

nomisma-ids-by-editor.sparql

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX prov:	<http://www.w3.org/ns/prov#>

SELECT ?concept ?label ?editor ?orcid ?date ?spreadsheet ?desc WHERE {
  BIND (<http://nomisma.org/editor/ameadows> as ?editor)
  
  {
    SELECT ?editor ?orcid WHERE {
      ?editor skos:exactMatch ?orcid FILTER (strStarts(str(?orcid), "https://orcid.org"))
    }
  }
  
  ?concept skos:changeNote ?prov ;
  	skos:prefLabel ?label FILTER (langMatches(lang(?label), "en"))
  {?prov prov:wasGeneratedBy ?activity}
  UNION {?prov prov:activity ?activity}
  ?activity a prov:Activity ;
  	prov:atTime ?date
  {?activity prov:wasAssociatedWith ?editor FILTER NOT EXISTS {?activity prov:used ?spreadsheet}}
  UNION {?activity prov:used ?spreadsheet 
        {?spreadsheet dcterms:creator ?editor }
        UNION {?spreadsheet dcterms:contributor ?editor}
        ?spreadsheet dcterms:description ?desc
        }
} ORDER BY ?label LIMIT 100

Copy and paste into the test SPARQL endpoint at http://admin.numismatics.org/nomisma/sparql