Threading macros for Scheme

threading.scm

(define-syntax ->
  (syntax-rules ()
    ((_ val)
     val)
    ((_ val (f args ...) rest ...)
     (-> (f val args ...)
         rest ...))
    ((_ val f rest ...)
     (-> (f val)
         rest ...))))

(define-syntax ->>
  (syntax-rules ()
    ((_ val)
     val)
    ((_ val (f args ...) rest ...)
     (->> (f args ... val)
          rest ...))
    ((_ val f rest ...)
     (->> (f val)
          rest ...))))

(define-syntax as->
  (syntax-rules ()
    ((_ val name)
     val)
    ((_ val name (f args ...) rest ...)
     (let ((name val))
       (as-> (f args ...) name
             rest ...)))
    ((_ val name f rest ...)
     (as-> val name (f)
           rest ...))))

(define-syntax if->
  (syntax-rules ()
    ((_ val (then args ...) else)
     (let ((x val))
       (if x
           (then x args ...)
           else)))))

(define-syntax if->>
  (syntax-rules ()
    ((_ val (then args ...) else)
     (let ((x val))
       (if x
           (then args ... x)
           else)))))

(define-syntax if->*
    (syntax-rules ()
      ((_ (then args ...) else val)
       (let ((x val))
         (if x
             (then x args ...)
             else)))))

  (define-syntax if->>*
    (syntax-rules ()
      ((_ (then args ...) else val)
       (let ((x val))
         (if x
             (then args ... x)
             else)))))