PKGBUILD

# Maintainer: Alexander Epaneshnikov <alex19ep@archlinux.org>
# Contributor: Steve Holmes <steve.holmes88@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=orca-git
pkgver=50.0.r65.gb02c51113
pkgrel=1
pkgdesc="Screen reader for individuals who are blind or visually impaired (development version)"
url="https://wiki.gnome.org/Projects/Orca"
arch=('x86_64')
license=('LGPL-2.1-or-later')
depends=(
  at-spi2-core
  brltty
  gsettings-desktop-schemas
  gst-plugins-base # playbin, audiotestsrc, basic decoders
  gst-plugins-good # pulsesink, more decoders
  gtk3
  liblouis
  libwnck3
  python-dasbus
  python-gobject
  python-setproctitle
  python-psutil
  python-cairo
  python-dbus
  speech-dispatcher
  xorg-xkbcomp
  xorg-xmodmap
)
checkdepends=(python-pytest python-pytest-mock)
makedepends=(
  git
  itstool
  yelp-tools
  meson
  rust
)
groups=('gnome')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=(
  "${pkgname%-git}::git+https://gitlab.gnome.org/GNOME/${pkgname%-git}.git"
  "mathcat-py::git+https://github.com/daisy/MathCATForPython.git"
)
sha256sums=('SKIP' 'SKIP')

prepare() {
  # Place mathcat-py source where meson expects the subproject
  ln -sf "${srcdir}/mathcat-py" "${pkgname%-git}/subprojects/mathcat-py"
  # Apply orca's patch files for the subproject build system
  cp -r "${pkgname%-git}"/subprojects/packagefiles/mathcat-py/* "${srcdir}/mathcat-py/"
}

pkgver() {
	cd "${pkgname%-git}"
	# cutting off 'ORCA_' prefix that presents in the git tag
	git describe --long | sed 's/^ORCA_//;s/\([^-]*-g\)/r\1/;s/_/-/g;s/-/./g'
}

build() {
  arch-meson ${pkgname%-git} build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs || true
}

package() {
  meson install -C build --destdir "$pkgdir"
}