button to trigger kaku switch

panic-button.ino

#include "Arduino.h"
#include "Wire.h"
#include "Qduino.h" // https://www.sparkfun.com/products/13614
#include "RemoteSwitch.h" // https://github.com/jccprj/RemoteSwitch-arduino-library

fuelGauge battery;  // initialize the library

qduino q;
KaKuSwitch kaKuSwitch(5);

const int led = 9;
const int button = 0;
bool lightState = 0;
long lastTrigger = 0;

void setup(){
 Wire.begin(); 
 battery.setup();
 
 q.setup();

 pinMode(led, OUTPUT);
 pinMode(button, INPUT_PULLUP);

 attachInterrupt(digitalPinToInterrupt(button), changeLight, CHANGE);

 analogWrite(led, 0);
}

void loop(){
  pulseLed(10);
  checkBattery();
  turnLightOff();
}

void checkBattery() {
  int charge = battery.chargePercentage();

  battery.reset();
  
  if(charge >= 75) {
    q.setRGB(GREEN);
  } 
  else if(charge >= 50 && charge < 75) {
    q.setRGB(YELLOW);
  } 
  else if(charge >= 25 && charge < 50) {
    q.setRGB(ORANGE);
  } 
  else {
    q.setRGB(RED);
  }
}

void pulseLed(int waitms) {
  for(int i=0; i<255; i++) {
    analogWrite(led, i);
    delay(waitms);
  }
  for(int i=255; i>0; i--) {
    analogWrite(led, i);
    delay(waitms);
  }
}

void changeLight() {
  if((millis() - lastTrigger) > 1000) {
    lastTrigger = millis();
    
    lightState = !lightState;
  
    kaKuSwitch.sendSignal('A',1,lightState);
  }
}

void turnLightOff() {
  if(lightState && (millis() - lastTrigger) > (60*1000)) {
    changeLight();
  }
}