Il nuovo SessionStoreBackup è pensato per Firefox 57 e superiori, e lavora ora sui nuovi jsonlz4 compressi. Leggi l'articolo dedicato su https://wp.me/pdQ5q-8PN

SessionStoreBackup.cmd

REM =====================================================================================================================
REM NOME DEL PROFILO (DA CONFIGURARE)
REM Se non sai cosa fare, leggi http://wp.me/pdQ5q-1BY
REM =====================================================================================================================
set NOMEPROFILO=TUOPROFILO.default

REM =====================================================================================================================
REM NON TOCCARE NIENTE DA QUI IN POI!
REM =====================================================================================================================

@echo off
setlocal enabledelayedexpansion

cls
echo SessionStoreBackup 0.6 per Firefox 55+
echo ult.mod. 5/6/17, GSolone (gf.solone@mozillaitalia.org)
echo info: http://wp.me/pdQ5q-1BY
echo ---------------------------------------------------------------------------------

:Preparazione
echo;
echo Lettura directory e file di salvataggio sessione ...
echo;

set sessionFileDir=%appdata%\Mozilla\Firefox\Profiles\%NOMEPROFILO%\sessionstore-backups\
set sessionBackupDir=%appdata%\Mozilla\Firefox\Profiles\%NOMEPROFILO%\
set sessionFileName=recovery
set sessionFileSuffix=.js

if not exist "%sessionFileDir%%sessionFileName%%sessionFileSuffix%" (echo File di sessione non trovato, termino il programma. && GOTO :End)
if not exist "%sessionBackupDir%SessionStoreBackup" mkdir %sessionBackupDir%SessionStoreBackup

:MD5
set /a count=1 
for /f "skip=1 delims=:" %%a in ('CertUtil -hashfile "%sessionFileDir%%sessionFileName%%sessionFileSuffix%" MD5') do (
  if !count! equ 1 set "md5source=%%a"
  set/a count+=1
)
set "md5source=%md5source: =%
echo Hash file sorgente %md5source%

set /a count=1
for /f "skip=1 delims=:" %%a in ('CertUtil -hashfile "%sessionBackupDir%SessionStoreBackup\%sessionFileName%%sessionFileSuffix%" MD5') do (
  if !count! equ 1 set "md5dest=%%a"
  set/a count+=1
)
set "md5dest=%md5dest: =%
echo Hash file backup %md5dest%
echo;

if %md5source% == %md5dest% (echo File di sessione esistente, backup non necessario, termino il programma. && GOTO :End) 


:Start
IF NOT EXIST "%sessionBackupDir%%sessionFileName%%sessionFileSuffix%" (
echo Creo il file di backup ...
echo;
copy "%sessionFileDir%%sessionFileName%%sessionFileSuffix%" "%sessionBackupDir%%sessionFileName%%sessionFileSuffix%"
echo;
echo Sposto il file nella cartella di backup ...
echo;
move "%sessionBackupDir%%sessionFileName%%sessionFileSuffix%" "%sessionBackupDir%SessionStoreBackup\"
echo;
echo Backup completato in
echo "%sessionBackupDir%SessionStoreBackup\%sessionFileName%%sessionFileSuffix%"
echo;
)

:End
endlocal