PKGBUILD

# Maintainer: graysky <therealgraysky AT protonmail DOT com>
# Contributor: germar <germar DOT reitze AT gmail DOT com>

pkgname=(backintime backintime-cli)
_pkgname="backintime"
#_commit=88d19d42e9128f60b8952a64ed1fff23bd28108f
_commit=2121c60c882e8fa16de6439a27e91b046118291d
pkgver=1.3.2
pkgrel=3
arch=(any)
url="https://github.com/bit-team/backintime"
license=(GPL)
makedepends=(python)
checkdepends=(openssh python-dbus rsync systemd python-pyfakefs)
source=("$_pkgname-$pkgver.tar.gz::https://github.com/bit-team/$_pkgname/archive/$_commit.tar.gz"
    001-fix-test-test_tools-add-sleep-for-flaky-systems.patch::https://patch-diff.githubusercontent.com/raw/bit-team/backintime/pull/1214.patch)
b2sums=('c7517457ebb1b87539b0a140573132e11b956e7eb6b26a094cc765c971452a2323b9d1d856a33445448717f05402f27ec9ec6594f568c9018132a58618077134'
        'f840b40cebb5a360db319fddb404217cff94e62df36e155ebd41ff44cf357a29697c461e83b878d044230f902b91beaaccf604d12e68d93f58c0b5360237cb7e')

prepare() {
  cd "$_pkgname-$_commit"
}

build() {
  cd "$_pkgname-$_commit/common"
  ./configure --python --no-fuse-group
  make

  cd "$srcdir/$_pkgname-$_commit/qt"
  ./configure --python
  make
}

check() {
  cd "$_pkgname-$_commit/common"
  
  make test
}

package_backintime-cli() {
  pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. CLI version."
  depends=('cron' 'fuse2' 'openssh' 'python-dbus' 'python-keyring' 'rsync'
           'python-packaging' 'python-pyfakefs')
  optdepends=('backintime: QT5 GUI version'
  'encfs: encrypted filesystem in user-space'
  'pm-utils: for laptops allows an option to not snapshot on battery'
  'sshfs: FUSE client based on the ssh file transfer protocol')

  cd "$_pkgname-$_commit/common"
  make DESTDIR="$pkgdir" install
}

package_backintime() {
  pkgdesc="Simple backup system inspired from the Flyback Project and TimeVault. QT5 GUI version."
  depends=("backintime-cli=$pkgver" 'libnotify' 'polkit' 'python-dbus' 'python-pyqt5' 'xorg-xdpyinfo')
  # note users can optionally install EITHER kompare OR meld but not both!
  optdepends=('kompare: diff/patch frontend'
  'meld: diff/patch frontend'
  'python-keyring: store and access passwords safely')

  cd "$_pkgname-$_commit/qt"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=8 sts=2 sw=2 et: