spectredata.fs

module IsaacStuff =
    type TableRow =
        | Empty
        | DataRow of string array
    type TableSetting =
        | Border of TableBorder
        | Column of TableColumn
        | Row of TableRow
    let createTable settings =
        settings
        |> List.fold(fun (table:Table) setting ->
            match setting with
            | Border border ->
                table.Border <- border
                table
            | Column column ->
                table.AddColumn column
            | Row Empty ->
                table.AddEmptyRow()
            | Row (DataRow names) ->
                table.AddRow names) (Table())
    let render = AnsiConsole.Render

open IsaacStuff

let layout = [
    Border TableBorder.Rounded
    Column (TableColumn "[u]Name[/]")
    Column (TableColumn "[u]Age[/]")
    Column (TableColumn "[u]Department[/]")
    Row (DataRow [| "Hello"; "[red]World![/]"; "" |])
    Row Empty
    Row (DataRow [| "[blue]Bonjour[/]"; "[white]le[/]"; "[red]monde![/]" |])
]

layout
|> createTable
|> render