Fix GNU autotools errors in lxappearance2-git PKGBUILD

PKGBUILD

# Maintainer: Ner0
# Contributor: Dave Reisner <d@falconindy.com>
# Contributor: Keshav P R <skodabenz at rocketmail dot com>
# Contributor: Isaac Aggrey <isaac.aggrey@gmail.com>

pkgname=lxappearance2-git
pkgrel=2
pkgver=0.5.2.15.g67e9745
pkgdesc="GTK+ theme switcher for LXDE (manages icons and fonts) - Version 2 - GIT"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://lxde.org/"
depends=('gtk2' 'intltool')
makedepends=('git' 'docbook-xsl' 'pkgconfig')
conflicts=('lxappearance')
provides=('lxappearance')
source=('git://lxde.git.sourceforge.net/gitroot/lxde/lxappearance')

pkgver() {
  cd lxappearance
  git describe | tr - .
}

prepare() {
  cd lxappearance

  sed -i 's/foreign/foreign subdir-objects/' ./configure.ac
  sed -i 's/xml_purge_SOURCES=.*/xml_purge_SOURCES=xml-purge.c/' ./src/Makefile.am

  autoreconf -vfi
  intltoolize -f
}

build() {
  cd lxappearance
  ./configure --prefix=/usr --sysconfdir=/etc --enable-man
  make
}

package() {
  cd lxappearance
  make DESTDIR="$pkgdir/" install
}