Generates a CSV file describing, for each hour of each day of the week: "commit count / added lines / removed lines". An example of generated CSV is provided (generated by running the script on the 'git' git repository).

example.csv

git-weekly-stats.sh

#!/bin/bash

git log --format=format:"%aD" --numstat | gawk '

BEGIN {
    FS="\t"
}

match($0, /^([[:alnum:]]{3}), [[:digit:]]+ [[:alpha:]]{3} \
[[:digit:]]+ ([[:digit:]]+):[[:digit:]]+:[[:digit:]]+/, mt) {
    cur_day = mt[1]
    cur_hour = +mt[2]
    days[cur_day][cur_hour]["cc"] += 1
}

NF == 3 {
    days[cur_day][cur_hour]["in"] += +$1
    days[cur_day][cur_hour]["out"] += +$2
}

function print_day(name, day) {
    printf "%s,", name
    printf "%d/%d/%d", day[0]["cc"], day[0]["in"], day[0]["out"]
    for (hour = 1; hour < 24; hour++) {
        printf ";%d/%d/%d", day[hour]["cc"], day[hour]["in"], day[hour]["out"];
    }
    printf "\n"
}

END {
    printf "day,lines\n"
    for (day in days)
        print_day(day, days[day]);
}

'