Fuse equivalent resources by hash

fuse_equivalent_hashes.sparql

PREFIX : <http://example.com/>

DELETE {
  ?r ?outP ?outO .
  ?inS ?inP ?r .
}
WHERE {
  {
    SELECT (SAMPLE(?r) AS ?sampleR) ?hash
    WHERE {
      {
        SELECT ?r
               # Compute hashes from resource's description.
               (SHA1(CONCAT(GROUP_CONCAT(STR(?p); separator = ""),
                            GROUP_CONCAT(STR(?o); separator = ""))) AS ?hash)
        WHERE {
          # Select resources to fuse. 
          ?r a :C ;
            ?p ?o .
        }
        GROUP BY ?r
      }
    }
    GROUP BY ?hash
  }
  # Hashes must be computed twice, since we cannot have both
  # the aggregate (?sampleR) and the aggregated bindings (?r).
  {
    SELECT ?r
           (SHA1(CONCAT(GROUP_CONCAT(STR(?p); separator = ""),
                        GROUP_CONCAT(STR(?o); separator = ""))) AS ?hash)
    WHERE {
      ?r a :C ;
        ?p ?o .
    }
    GROUP BY ?r
  }
  FILTER (!sameTerm(?r, ?sampleR))
  ?r ?outP ?outO .
  OPTIONAL {
    ?inS ?inP ?r .
  }
}