gistfile1.txt

role Poly { }

class PolyReal does Poly { }

class PolyVar does Poly {
    has $.name;
}

class PolyExpr does Poly {
    has $.operation;
    has $.left;
    has $.right;

    submethod BUILD(:$left is raw, :$right is raw, :$!operation) {
        $!left = extract-var($left);
        $!right = extract-var($right);
    }

    sub extract-var(\maybe-real) {
        maybe-real ~~ PolyReal
            ?? PolyVar.new(name => maybe-real.VAR.name)
            !! maybe-real
    }
}

sub poly-node(\left, \right, \op) {
    PolyExpr.new(left => left, right => right, operation => op)
}

multi infix:<+>(Poly \left, Poly \right) {
    poly-node(left, right, '+')
}
multi infix:<+>(Real \left, Poly \right) {
    poly-node(left, right, '+')
}
multi infix:<+>(Poly \left, Real \right) {
    poly-node(left, right, '+')
}
multi infix:<->(Poly \left, Poly \right) {
    poly-node(left, right, '-')
}
multi infix:<->(Real \left, Poly \right) {
    poly-node(left, right, '-')
}
multi infix:<->(Poly \left, Real \right) {
    poly-node(left, right, '-')
}
multi infix:<*>(Poly \left, Poly \right) {
    poly-node(left, right, '*')
}
multi infix:<*>(Real \left, Poly \right) {
    poly-node(left, right, '*')
}
multi infix:<*>(Poly \left, Real \right) {
    poly-node(left, right, '*')
}

my PolyReal $X;

say $X * ($X + 2)