PKGBUILD

# Maintainer: Vlad M. <vlad@archlinux.net>
# Contributor: Mario Rodas
# Contributor: Oozyslug <oozyslug at gmail dot com>
# Contributor: koral <koral at mailoo dot org>
# Contributor: k2s <martin minka at gmail dot com>

pkgname=nix
pkgver=1.11.2
pkgrel=2
pkgdesc="A purely functional package manager"
arch=('i686' 'x86_64')
url="https://nixos.org/nix"
license=('LGPL')
depends=('perl-www-curl' 'perl-dbd-sqlite' 'gc' 'libsodium')
makedepends=('bzip2' 'gc' 'openssl')
source=("http://nixos.org/releases/$pkgname/$pkgname-$pkgver/$pkgname-$pkgver.tar.xz"
        "https://raw.githubusercontent.com/wmertens/nix/patch-5/scripts/nix-profile.sh.in")
sha256sums=('fc1233814ebb385a2a991c1fb88c97b344267281e173fea7d9acd3f9caf969d6'
            '6410c08b81e6c7e150abe066e320686ff67d21c0afab62f0ab62da704097d0e4')

prepare () {
  # patch until this will not be merged https://github.com/NixOS/nix/pull/452
  cp -f "$srcdir/nix-profile.sh.in" "$pkgname-$pkgver/scripts/nix-profile.sh.in"
}

build () {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr \
              --libexecdir="/usr/lib/$pkgname" \
              --sysconfdir=/etc \
              --enable-gc
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}