python-vcstools PKGBUILD

PKGBUILD

# Maintainer: Kartik Mohta <kartikmohta@gmail.com>

pkgbase=('python-vcstools')
pkgname=('python-vcstools' 'python2-vcstools')
_module='vcstools'
pkgver='0.1.39'
pkgrel=1
pkgdesc="VCS/SCM source control library for svn, git, hg, and bzr"
url="http://wiki.ros.org/vcstools"
depends=()
makedepends=('python-setuptools' 'python2-setuptools')
license=('BSD')
arch=('any')
source=("https://files.pythonhosted.org/packages/source/v/vcstools/vcstools-${pkgver}.tar.gz")
md5sums=('c20e19e5a5b83520329bd2040bccb375')

prepare() {
    cp -a "${srcdir}/${_module}-${pkgver}"{,-python2}
}

build() {
    cd "${srcdir}/${_module}-${pkgver}"
    python setup.py build

    cd "${srcdir}/${_module}-${pkgver}-python2"
    python2 setup.py build
}

package_python-vcstools() {
    depends+=('python' 'python-dateutil' 'python-yaml')
    cd "${srcdir}/${_module}-${pkgver}"
    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}

package_python2-vcstools() {
    depends+=('python2' 'python2-dateutil' 'python2-yaml')
    cd "${srcdir}/${_module}-${pkgver}-python2"
    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}