Absinthe Jailbreak Installer Assistant for iPhone 4S and iPad 2

absinthe.cmd

@echo off & setlocal
rem Absinthe Jailbreak Installer Assistant
rem Written by Ad@m <http://adam.hbang.ws>
rem Licensed under the MIT License <http://adam.mit-license.org>
rem --------------------------------------
rem To use, download download and unzip this batch file from
rem <http://gist.github.com/gists/1653393/download>, then download
rem Absinthe from <http://idownloadblog.com/iphone-downloads>.
rem Now right click this batch file and run as administrator.
title Absinthe Jailbreak
cls
echo Absinthe Jailbreak Batch File
echo Written by Ad@m ^<http://adam.hbang.ws^>
echo.
pushd %~dp0
if not exist "cinject.exe" (
	title Absinthe Jailbreak [Error]
	echo Please copy cinject.exe, cinject and the payload folder to:
	echo.
	echo  %cd%
	echo.
	echo ...and run this script again.
	call :attn
	color 4f
	start %~dp0
	echo Press any key to exit.
	pause>nul
	color
	popd
	exit /b
)
reg query "HKU\S-1-5-19">nul
if "%ERRORLEVEL%" == "1" (
	title Absinthe Jailbreak [Error]
	echo Administrator privileges required. Please right click %~nx0 and
	echo choose "Run as Administrator".
	call :attn
	color 4f
	start %~dp0
	echo Press any key to exit.
	pause>nul
	color
	popd
	exit /b
)
title Absinthe Jailbreak [Prologue]
echo  Please unlock your device so it is showing the home screen. Press any key once
echo                                you have done this.
pause>nul
cls
title Absinthe Jailbreak [Installing Profile...]
echo ================================================================================
cinject -i payloads\jailbreak.mobileconfig
echo.
echo ================================================================================
title Absinthe Jailbreak [Action Required]
echo    On your device, an Install Profile page should appear, please tap install.
echo   If you're asked for a password, just leave it blank and tap next. Press any
echo                            key once you've done this.
call :attn
pause>nul
cls
echo ================================================================================
title Absinthe Jailbreak [Action Required]
echo    Another command prompt window will now appear, please do not close it. You
echo            will see warning messages, but they can be safely ignored.
echo.
echo  Once you notice the messages stop, on your device, go to Settings then General
echo     and Network, then turn on VPN. Don't worry about the error that appears.
echo                 After your device reboots, it will be jailbroken!
call :attn
ping -n 5 127.0.0.1>nul
title Absinthe Jailbreak [Running Payload...]
cinject -j payloads
title Absinthe Jailbreak [Opening Syslog...]
start "Absinthe Jailbreak [Syslog]" cmd /c cinject -w
echo.
echo ================================================================================
title Absinthe Jailbreak [Epilogue]
echo   If you would like to donate to the developers of this jailbreak, press Y and
echo                   enter, otherwise press N and enter. Have fun!
echo.
echo ================================================================================
set /p "thanks=Enter your choice: "
set donate=false
if "%thanks%" == "y" (set donate=true)
if "%thanks%" == "Y" (set donate=true)
if "%donate%" == "true" (
	start https://www.paypal.com/cgi-bin/webscr?cmd=_s-xclick^&hosted_button_id=DPFUPCEAYUD4L
)
ping -n 1 127.0.0.1>nul
title
popd
goto :eof

:attn
if exist "%windir%\system32\sndrec32.exe" (
	start /min sndrec32 /play /close %windir%\media\ding.wav 
) else if exist "%windir%\system32\mplay32.exe" (
	start /min mplay32 /play /close %windir%\media\ding.wav
)
ping -n 1 127.0.0.1>nul
color c0
ping -n 1 127.0.0.1>nul
color
ping -n 1 127.0.0.1>nul
color 4f
ping -n 1 127.0.0.1>nul
color
ping -n 1 127.0.0.1>nul
goto :eof