Created
February 10, 2019 17:16
-
-
Save lahwaacz/c0d6e39094101dd069a9fe3835ec620e to your computer and use it in GitHub Desktop.
updated PKGBUILD for AUR/cairo-infinality-ultimate
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
# Maintainer: Jan de Groot <jgc@archlinux.org> | |
# Contributor: Brice Carpentier <brice@daknet.org> | |
pkgname=cairo-infinality-ultimate | |
_name=cairo | |
pkgver=1.16.0 | |
pkgrel=1 | |
pkgdesc="2D graphics library with support for multiple output devices" | |
url="https://cairographics.org/" | |
arch=(x86_64) | |
license=(LGPL MPL) | |
provides=(cairo) | |
conflicts=(cairo) | |
depends=(libpng libxrender libxext fontconfig pixman glib2 lzo) | |
makedepends=(librsvg gtk2 poppler-glib libspectre gtk-doc valgrind git) | |
checkdepends=(ttf-dejavu gsfonts) | |
_commit=3ad43122b21a3299dd729dc8462d6b8f7f01142d # tags/1.16.0^0 | |
source=("git+https://gitlab.freedesktop.org/cairo/cairo.git#commit=$_commit" | |
cairo-make-lcdfilter-default.patch | |
cairo-respect-fontconfig_pb.patch | |
cairo-server-side-gradients.patch | |
cairo-webkit-html5-fix.patch) | |
sha1sums=('SKIP' | |
'b0cc2466cc5479f055ca2148cfa37fe13a1e78a6' | |
'd8ffcb4c4745f7e61671109362a80a872ac989d3' | |
'72ecf2dda8462e1588512de257ccbe18642d507f' | |
'5bff494f52a16114f4cf6d04bfb0b9d7c4e9da23') | |
prepare(){ | |
cd $_name | |
patch -Np1 -i "${srcdir}"/cairo-make-lcdfilter-default.patch | |
patch -Np1 -i "${srcdir}"/cairo-respect-fontconfig_pb.patch | |
patch -Np1 -i "${srcdir}"/cairo-server-side-gradients.patch | |
patch -Np1 -i "${srcdir}"/cairo-webkit-html5-fix.patch | |
# Update gtk-doc | |
cp /usr/share/aclocal/gtk-doc.m4 build/aclocal.gtk-doc.m4 | |
cp /usr/share/gtk-doc/data/gtk-doc.make build/Makefile.am.gtk-doc | |
NOCONFIGURE=1 ./autogen.sh | |
} | |
build() { | |
cd $_name | |
./configure --prefix=/usr \ | |
--sysconfdir=/etc \ | |
--localstatedir=/var \ | |
--disable-static \ | |
--disable-gl \ | |
--enable-tee \ | |
--enable-svg \ | |
--enable-ps \ | |
--enable-pdf \ | |
--enable-gobject \ | |
--enable-gtk-doc \ | |
--enable-full-testing \ | |
--enable-test-surfaces | |
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool | |
make | |
} | |
check() { | |
cd cairo | |
# FIXME: tests don't pass | |
env CAIRO_TEST_TARGET=image \ | |
CAIRO_TEST_TARGET_FORMAT=rgba \ | |
CAIRO_TESTS='!pthread-show-text' make -k check || : | |
} | |
package() { | |
cd $_name | |
make DESTDIR="$pkgdir" install | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment