PKGBUILD

pkgname=nnn-luuk-git
pkgver=3.5.r252.g4008ead
pkgrel=1
pkgdesc="The fastest terminal file manager ever written."
arch=(x86_64)
url='https://github.com/luukvbaal/nnn'
license=(BSD)
depends=('bash')
optdepends=(
  'atool: for more archive formats'
  'libarchive: for more archive formats'
  'zip: for zip archive format'
  'unzip: for zip archive format'
  'trash-cli: to trash files'
  'sshfs: mount remotes'
  'rclone: mount remotes'
  'fuse2: unmount remotes'
  'xdg-utils: desktop opener'
)
makedepends=(git)
provides=(nnn)
conflicts=(nnn)
source=("nnn::git+https://github.com/luukvbaal/nnn"
        "nord-icons.diff::https://github.com/jarun/nnn/compare/master...luukvbaal:nord-icons.diff")
md5sums=('SKIP' 'SKIP')

pkgver() {
  cd nnn
  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g;s/v//g'
}

prepare() {
  cd nnn
  sed -i 's/install: all/install:/' Makefile
	patch --forward --strip=1 --input="${srcdir}"/nord-icons.diff
}

build() {
  cd nnn
  make O_NERD=1 O_NOSSN=1 strip
}

package() {
  cd nnn
  make DESTDIR="${pkgdir}" PREFIX=/usr install

  install -Dm644 misc/auto-completion/zsh/_nnn "${pkgdir}/usr/share/zsh/site-functions/_nnn"
  install -Dm644 -t "${pkgdir}/usr/share/nnn/quitcd/" misc/quitcd/quitcd.bash_zsh
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}