sp_drop_constraints.sql

    -- Adapted from Jon Galloway: http://weblogs.asp.net/jgalloway/archive/2006/04/12/442616.aspx
    -- This couldn't handle multiple schemas in the same table. Fixed.
    -- Removed concat to widen support to earlier versions of MSSQL.

    CREATE PROCEDURE [dbo].[sp_drop_constraints]

        @database      [sysname]     = NULL,
        @table         [sysname],
        @verbose       [bit]         = 0
    AS
    BEGIN

        IF @database IS NULL
        BEGIN
            SET @database = DB_NAME();
        END

        DECLARE @crlf  [varchar](max) = CHAR(13) + CHAR(10);
        DECLARE @sql   [nvarchar](max);

        WHILE EXISTS
        (
            SELECT *
            FROM [INFORMATION_SCHEMA].[TABLE_CONSTRAINTS]
            WHERE [CONSTRAINT_CATALOG] = @database
              AND [TABLE_NAME] = @table
              AND [CONSTRAINT_TYPE] != 'PRIMARY KEY'
        )
        BEGIN
            SELECT @sql = 'ALTER TABLE [' + @database + '].[' + CONSTRAINT_SCHEMA + '].[' + TABLE_NAME + ']'  + @crlf +
                          'DROP CONSTRAINT [' + REPLACE([CONSTRAINT_NAME], ']', ']]') + ']'  + @crlf
            FROM [INFORMATION_SCHEMA].[TABLE_CONSTRAINTS]
            WHERE [CONSTRAINT_CATALOG] = @database
              AND [TABLE_NAME] = @table
              AND [CONSTRAINT_TYPE] != 'PRIMARY KEY';

            IF @verbose = 1
            BEGIN
                PRINT @sql;
                PRINT '';
            END

            EXEC [sys].[sp_executesql] @sql

        END

    END