python-pycrypto

PKGBUILD

# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>

pkgbase=python-pycrypto
pkgname=('python-pycrypto' 'python2-pycrypto')
pkgver=2.6.1
pkgrel=2
license=('BSD')
arch=('x86_64')
url='http://www.pycryptodome.org/'
makedepends=('gmp' 'python-setuptools' 'python2-setuptools')
source=("pycrypto-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/60/db/645aa9af249f059cc3a368b118de33889219e0362141e75d4eaf6f80f163/pycrypto-${pkgver}.tar.gz")
md5sums=("55a61a054aa66812daf5161a0d5d7eda")

prepare() {
  cp -a "pycrypto-${pkgver}"{,-python2}
}

build() {
  cd "$srcdir/pycrypto-${pkgver}"
  python setup.py build

  cd "$srcdir/pycrypto-${pkgver}-python2"
  python2 setup.py build
}

check() {
  cd "$srcdir/pycrypto-${pkgver}"
  python setup.py test

  cd "$srcdir/pycrypto-${pkgver}-python2"
  python2 setup.py test
}

package_python-pycrypto() {
  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 3."
  depends=('python' 'gmp')
  conflicts=('python-crypto')
  provides=('python-crypto')
  replaces=('python-crypto')

  cd "pycrypto-${pkgver}"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  #install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
}

package_python2-pycrypto() {
  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 2."
  depends=('python2' 'gmp')
  conflicts=('python2-crypto')
  provides=('python2-crypto')
  replaces=('python2-crypto')

  cd "pycrypto-${pkgver}-python2"
  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
  #install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
}