Dumping constraints

dump.gradle

import javax.inject.Inject

plugins {
    id 'java-library'
}
repositories {
    mavenCentral()
}

configurations {
    declaredConstraints
}

def provider = layout.buildDirectory.file("constraints.txt")

dependencies {
    declaredConstraints platform('org.springframework.boot:spring-boot-dependencies:2.1.9.RELEASE')

    components.all(ExtractConstraintsFromPlatform) {
        params(provider)
    }
}


task showConstraints {
    doLast {
        configurations.declaredConstraints.resolve()
        println provider.get().asFile.text
    }
}

class ExtractConstraintsFromPlatform implements ComponentMetadataRule {
    private final Provider<RegularFile> outputFile

    @Inject
    ExtractConstraintsFromPlatform(Provider<RegularFile> out) {
        outputFile = out
    }


    void execute(ComponentMetadataContext context) {
        Set<String> declared = []
        def out = outputFile.get().asFile
        out.parentFile.mkdirs()
        out.delete()
        context.details.allVariants {
            withDependencyConstraints {
                out.withWriterAppend { writer ->
                    it.each {
                        if (declared.add(it)) {
                            writer.println(it)
                        }
                    }
                }
            }
        }
    }
}