build.boot.clj

build.boot.clj

(set-env!
  :source-paths #{"src"}
  :dependencies '[[ring "1.4.0"]])

(require '[ring.adapter.jetty :refer [run-jetty]]
         '[ring.middleware.reload :refer [wrap-reload]])

(defn start-server [port handler]
  (boot.util/info "starting server on port %d\n" port)
  (let [server (run-jetty handler {:port port :join? false})]
    (fn []
      (boot.util/info "stopping server on port %d\n" port)
      (.stop server))))

(defn cp-dirs
  "Directories on classpath -- ring-reload will reload code in these dirs."
  []
  (->> (Thread/currentThread)
       (.getContextClassLoader)
       (iterate (memfn getParent))
       (take-while identity)
       (mapcat (memfn getURLs))
       (filter (comp (memfn isDirectory) clojure.java.io/file))
       (map (memfn getPath))))

(def app
  (-> (fn [req]
        {:status  200
         :headers {"content-type" "text/plain"}
         :body    "hello world"})
      (wrap-reload {:dirs (cp-dirs)})))

(deftask serve
  [p port PORT int "The port to listen on (default 8080)."]
  (let [port   (or port 8080)
        server (delay (start-server port #'app))]
    (cleanup (@server))
    (with-pass-thru [fs] @server)))