Skip to content

Instantly share code, notes, and snippets.

@mkrus
Last active December 19, 2015 22:48
Show Gist options
  • Star 1 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
  • Save mkrus/6030102 to your computer and use it in GitHub Desktop.
Save mkrus/6030102 to your computer and use it in GitHub Desktop.
This should get you most of the way to build Qt 5.1.0 with Visual Studio 2010 64 bits
@rem http://qt-project.org/doc/qt-5.1/qtdoc/requirements-win.html
@rem http://qt-project.org/doc/qt-5.1/qtdoc/install-win.html
@rem http://qt-project.org/forums/viewthread/23048
call "C:\Program Files (x86)\Microsoft Visual Studio 10.0\VC\vcvarsall.bat" x64
@echo off
@echo --
set VER=5.1
set MINOR_VERSION=0
set BUILD_LOG=%CD%\build_qt.log
@del %BUILD_LOG%
set FINAL_DIST_DIR=c:\Qt\%VER%.%MINOR_VERSION%-WIN64.VC10
rem e.g. C:\Qt\5.1.0-WIN64.VC10
if not exist qt-everywhere-opensource-src-%VER%.%MINOR_VERSION%.zip (
>> %BUILD_LOG% curl.exe -O -L http://download.qt-project.org/official_releases/qt/%VER%/%VER%.%MINOR_VERSION%/single/qt-everywhere-opensource-src-%VER%.%MINOR_VERSION%.zip
)
rem ALSO NEED TO GET PYTHON
if not exist c:\Ruby200-x64\bin\ruby.exe (
>> %BUILD_LOG% curl.exe -O -L http://dl.bintray.com/oneclick/rubyinstaller/rubyinstaller-2.0.0-p247-x64.exe?direct
echo Please install Ruby 64 bits
goto END
)
if not exist C:\Perl64\bin\perl.exe (
>> %BUILD_LOG% curl.exe -O -L http://downloads.activestate.com/ActivePerl/releases/5.16.3.1603/ActivePerl-5.16.3.1603-MSWin32-x64-296746.msi
echo Please install Perl 64 bits
goto END
)
if not exist icu (
>> %BUILD_LOG% curl.exe -O -L http://download.icu-project.org/files/icu4c/51.2/icu4c-51_2-Win64-msvc10.zip
>> %BUILD_LOG% rmdir /Q /S icu
>> %BUILD_LOG% unzip icu4c-51_2-Win64-msvc10.zip
)
set INCLUDE=%INCLUDE%;%CD%\icu\include
set LIB=%LIB%;%CD%\icu\lib64
set PATH=c:\Python27;C:\Perl64\bin;c:\Ruby200-x64\bin;%CD%\icu\bin64;%CD%;%PATH%
set QMAKESPEC=win32-msvc2010
rem Check that ruby, python, perl & jom are in your path
>> %BUILD_LOG% rmdir /Q /S qt-everywhere-opensource-src-%VER%.%MINOR_VERSION%
>> %BUILD_LOG% 7z x qt-everywhere-opensource-src-%VER%.%MINOR_VERSION%.zip
>> %BUILD_LOG% cd qt-everywhere-opensource-src-%VER%.%MINOR_VERSION%
set PATH=%CD%\qtbase\bin;%CD%\qtrepotools\bin;%CD%\gnuwin32\bin;%PATH%
> mvconfig.bat echo configure -prefix %FINAL_DIST_DIR% -opensource -confirm-license -make-tool jom -opengl desktop -debug-and-release -nomake test -nomake examples -skip quick1 -skip multimedia -skip serialport -skip sensors -skip qtwebkit-examples
>> %BUILD_LOG% call mvconfig.bat
>> %BUILD_LOG% jom
>> %BUILD_LOG% jom install
>> %BUILD_LOG% copy ..\icu\bin64\*.dll %FINAL_DIST_DIR%\bin
rem Copy lines below into qt.conf file in bin dir!
> %FINAL_DIST_DIR%\bin\qt.conf echo [Paths]
>> %FINAL_DIST_DIR%\bin\qt.conf echo Plugins = ../plugins
>> %FINAL_DIST_DIR%\bin\qt.conf echo Help = ../doc/help
:END
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment