A Tool that Splits PDF files by Chapter (as Bookmarks; uses pdftk)

pdf-autosplit.p6

#!/usr/bin/env perl6

use v6;

sub page-numbers-from-chapters($filename) {
    my $proc = run :out, 'pdftk', $filename, 'dump_data_utf8';
    my %bookmark;
    my @borders;
    sub handle-bookmark() {
        if %bookmark && (%bookmark<BookmarkLevel> // 0) == 1 {
            @borders.push(%bookmark<BookmarkPageNumber>);
        }
    }
    for $proc.out.lines -> $line {
        if $line eq 'BookmarkBegin' {
            handle-bookmark();
            %bookmark = ();
        }
        else {
            my @elems = $line.split(': ', 2);
            if @elems == 2 {
                %bookmark{@elems[0]} = @elems[1];
            }
        }
    }
    handle-bookmark();
    return @borders;
}

sub MAIN($filename = 'perl6regex-preview.pdf') {
    sub extract-chapter($from, $to, $number) {
        run 'pdftk', $filename, 'cat', $from ~ '-' ~ $to,
            'output', sprintf('chapter%02d.pdf', $number);
    }

    my $chapter = 0;
    my @borders = page-numbers-from-chapters($filename);
    for @borders.rotor(2 => -1) -> ($lower, $upper) {
        extract-chapter($lower, $upper - 1, $chapter);
        $chapter++;
    }
    # pdftk uses "r1" for the last page, "r2" for the
    # second-to-last etc.
    extract-chapter(@borders[*-1], 'r1', $chapter++);
}