Revised PKGBUILD for Text::Glob that supports local::lib

PKGBUILD

# Maintainer: jsteel <mail at jsteel dot org>
# Contributor: Alan Young <harleypig@gmail.com>

pkgname='perl-text-glob'
pkgver='0.09'
pkgrel='3'
pkgdesc="match globbing patterns against text"
_dist=Text-Glob
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs' purge)
depends=('perl')
url='http://search.cpan.org/dist/$_dist'
source=('http://search.cpan.org/CPAN/authors/id/R/RC/RCLAMP/Text-Glob-0.09.tar.gz')
md5sums=('1daa10e087f891c49b720a5c551a024b')

build() (
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 MODULEBUILDRC=/dev/null
  /usr/bin/perl Build.PL
  ./Build
)

check() (
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  ./Build test
)

package() (
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT
  ./Build install installdirs=vendor destdir="$pkgdir"
)