Skip to content

Instantly share code, notes, and snippets.

@nixpulvis nixpulvis/PKGBUILD
Last active Jul 22, 2019

Embed
What would you like to do?
Current ncurses PKGBUILD for Arch Linux (forked from the official https://git.archlinux.org/svntogit/packages.git/tree/trunk/PKGBUILD?h=packages/ncurses)
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>
pkgname=ncurses
pkgver=6.1
pkgrel=6
patchdate=20190706
pkgdesc='System V Release 4.0 curses emulation library'
arch=(x86_64)
url='https://invisible-island.net/ncurses/ncurses.html'
license=(MIT)
depends=(glibc gcc-libs)
provides=(libncurses++w.so libformw.so libmenuw.so libpanelw.so libncursesw.so)
# source=(ftp://ftp.invisible-island.net/ncurses/current/ncurses.tar.gz)
source=(ftp://ftp.invisible-island.net/ncurses/current/ncurses-6.1-20190706.tgz)
md5sums=('SKIP')
validpgpkeys=('C52048C0C0748FEE227D47A2702353E0F7E48EDB') # Thomas Dickey
build() {
cd $pkgname-$pkgver-$patchdate
./configure --prefix=/usr --mandir=/usr/share/man \
--with-pkg-config-libdir=/usr/lib/pkgconfig \
--with-shared --with-normal --without-debug --without-ada \
--enable-widec --enable-pc-files --with-cxx-binding --with-cxx-shared \
--with-manpage-format=normal
make
}
package() {
cd $pkgname-$pkgver-$patchdate
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# fool packages looking to link to non-wide-character ncurses libraries
for lib in ncurses ncurses++ form panel menu; do
echo "INPUT(-l${lib}w)" > "$pkgdir/usr/lib/lib${lib}.so"
ln -s ${lib}w.pc "$pkgdir/usr/lib/pkgconfig/${lib}.pc"
done
for lib in tic tinfo; do
echo "INPUT(libncursesw.so.${pkgver:0:1})" > "$pkgdir/usr/lib/lib${lib}.so"
ln -s libncursesw.so.${pkgver:0:1} "$pkgdir/usr/lib/lib${lib}.so.${pkgver:0:1}"
ln -s ncursesw.pc "$pkgdir/usr/lib/pkgconfig/${lib}.pc"
done
# some packages look for -lcurses during build
echo 'INPUT(-lncursesw)' > "$pkgdir/usr/lib/libcursesw.so"
ln -s libncurses.so "$pkgdir/usr/lib/libcurses.so"
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.