MoonSkybox.shader

Shader "Skybox/MoonSkybox"
{
//Displays a skybox with an overlayed texture that can be positioned as a moon
    Properties
    {
        _MoonTex ("Moon Texture", 2D) = "white" {}
		_SkyMap ("Sky Map", Cube) = "" {}
		_MoonDirection ("Moon Direction", Vector) = (0.4, 0.8, 0, 0)
		_MoonScale ("Moon Scale", Range(0.01, 1.0)) = 0.2
    }
    SubShader
    {
        Tags{ "Queue" = "Background" 
		"RenderType" = "Background"
		"PreviewType" = "Skybox" }

		Cull Back
		Lighting Off
		ZWrite Off


        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
				float3 viewDir : TEXCOORD1;
            };

            sampler2D _MoonTex;
            float4 _MoonTex_ST;
			float4 _MoonDirection;
			float _MoonScale;
			uniform samplerCUBE _SkyMap;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
				o.viewDir = mul(unity_ObjectToWorld, v.vertex).xyz - _WorldSpaceCameraPos;
                o.uv = TRANSFORM_TEX(v.uv, _MoonTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 backCol = texCUBE(_SkyMap, (i.viewDir));

				fixed3 moonVector = normalize(_MoonDirection.xyz);

				fixed3 diff = normalize(i.viewDir) - moonVector; //difference between view dir and moon dir

				//side vector
				fixed3 sideVector = normalize(cross(fixed3(0,1,0), moonVector));

				//up vector
				fixed3 upVector = normalize(cross(sideVector, moonVector));

				fixed2 moonUV = (fixed2(dot(sideVector,diff),dot(upVector,diff))/_MoonScale) +0.5;

				fixed4 moonColour = tex2D(_MoonTex, moonUV);

				moonColour.a = moonColour.a * (dot(normalize(i.viewDir), _MoonDirection) > 0); //Make sure only one moon


				return lerp(backCol, moonColour, moonColour.a);
            }
            ENDCG
        }
    }
}

MoonWithTransparentSkybox.shader

Shader "Skybox/MoonWithTransparentSkybox"
{
    Properties
    {
        _MoonTex ("Moon Texture", 2D) = "white" {}
		_SkyMap ("Sky Map", Cube) = "" {}
		_MoonDirection ("Moon Direction", Vector) = (0.4, 0.8, 0, 0)
		_MoonScale ("Moon Scale", Range(0.01, 1.0)) = 0.2
		_TransparencyThreshold ("Sky Transparency Threshold", Range(0.01, 1.0)) = 0.2
    }
    SubShader
    {
        Tags{ "Queue" = "Background" 
		"RenderType" = "Background"
		"PreviewType" = "Skybox" }

		Cull Back
		Lighting Off
		ZWrite Off


        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
				float3 viewDir : TEXCOORD1;
            };

            sampler2D _MoonTex;
            float4 _MoonTex_ST;
			float4 _MoonDirection;
			float _MoonScale;
			uniform samplerCUBE _SkyMap;
			float _TransparencyThreshold;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
				o.viewDir = mul(unity_ObjectToWorld, v.vertex).xyz - _WorldSpaceCameraPos;
                o.uv = TRANSFORM_TEX(v.uv, _MoonTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 backCol = texCUBE(_SkyMap, (i.viewDir));

		fixed3 moonVector = normalize(_MoonDirection.xyz);

		fixed3 diff = normalize(i.viewDir) - moonVector; //difference between view dir and moon dir

		//side vector
		fixed3 sideVector = normalize(cross(fixed3(0,1,0), moonVector));

		//up vector
		fixed3 upVector = normalize(cross(sideVector, moonVector));
		
		fixed2 moonUV = (fixed2(dot(sideVector,diff),dot(upVector,diff))/_MoonScale) +0.5;

		fixed4 moonColour = tex2D(_MoonTex, moonUV);

		moonColour.a = moonColour.a * (dot(normalize(i.viewDir), _MoonDirection) > 0); //Make sure only one moon

		fixed skyAlpha = (backCol.a-_TransparencyThreshold)/(1-_TransparencyThreshold);
		//Uses threshold because compression algorithms often discard RGB data if it was really completely transparent

		return lerp(backCol, lerp(moonColour,backCol,skyAlpha), moonColour.a); 

            }
            ENDCG
        }
    }
}