Arch build scripts for GNU Poke

jitter_PKGBUILD

_pkgname=jitter
pkgname=$_pkgname-git
pkgver=r596.745ba29
pkgrel=1
pkgdesc="Jitter"
arch=('i686' 'x86_64')
url="http://ageinghacker.net/git/cgit.cgi/jitter"
license=('GPL')
depends=()
makedepends=('git')
provides=('jitter')
conflicts=('jitter')
source=("$_pkgname::git+http://ageinghacker.net/git/cgit.cgi/jitter#commit=745ba29c15dd56c60a7ab0320e09c1ca705018b7")
md5sums=('SKIP')

pkgver() {
	cd $_pkgname
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd $_pkgname
	./bootstrap
	./configure --prefix=/usr
	make
}

check() {
	cd $_pkgname
	make check
}

package() {
	cd $_pkgname
	make DESTDIR="$pkgdir/" install
}

poke_PKGBUILD

_pkgname=gnupoke
pkgname=$_pkgname-git
pkgver=r2355.05f7804
pkgrel=1
pkgdesc="GNU poke is an interactive, extensible editor for binary data."
arch=('i686' 'x86_64')
url="http://www.jemarch.net/poke.html"
license=('GPL')
depends=('jitter')
makedepends=('git')
provides=('poke')
conflicts=('poke')
source=("$_pkgname::git+git://git.savannah.gnu.org/poke.git")
md5sums=('SKIP')

pkgver() {
	cd $_pkgname
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd $_pkgname
	./bootstrap --skip-po
	./configure --prefix=/usr --enable-debug --with-jitter=/usr
	make
}

check() {
	cd $_pkgname
	make check
}

package() {
	cd $_pkgname
	make DESTDIR="$pkgdir/" install
}