site-footer.xsl

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="hh xalan" version="1.0" xmlns:hh="http://www.hannonhill.com/XSL/Functions" xmlns:xalan="http://xml.apache.org/xalan">

  <xsl:output indent="yes" method="xml"/>
  <xsl:strip-space elements="*"/>

  <!-- Variables -->
  <!-- ================================================== -->


  <!-- Templates -->
  <!-- ================================================== -->
  <xsl:template match="site-configuration">

    <xsl:apply-templates select="department-information"/>

    <ul class="no-bullet inline-list">
      <li><a href="//www.rochester.edu/">University of Rochester</a></li>
      <li><a href="//www.rochester.edu/college/">AS&amp;E</a></li>
      <li>
        <a>
          <xsl:attribute name="href">
            <xsl:value-of select="department-information/department-url"/>
          </xsl:attribute>
          <xsl:value-of select="department-information/department-abbr"/>
        </a>
      </li>
    </ul>
    <!-- this will be the same for every footer -->
    <ul class="no-bullet inline-list">
      <li><a href="//www.rochester.edu/accessibility.html">Accessiblity</a></li>
      <li><a href="//text.rochester.edu/tt/referrer">Text</a></li>
      <li><a href="//www.rochester.edu/college/webcomm/">Web Communications</a></li>
    </ul>
    <p class="copyright"><small>&#169; 2019. All rights reserved.</small></p>
  </xsl:template>

  <xsl:template match="department-information">
    <p class="department-name">
      <xsl:value-of select="department-name"/>
    </p>
    <address>
      <dl>
        <dt class="show-for-sr">Address</dt>
        <dd>
          <xsl:call-template name="add-break-tags">
            <xsl:with-param name="currentNode" select="department-address"/>
          </xsl:call-template>
        </dd>
        <dt class="show-for-sr">Email</dt>
        <dd>
          <a>
            <xsl:attribute name="href">
              <xsl:text>mailto:</xsl:text><xsl:value-of select="department-email"/>
            </xsl:attribute>
            <xsl:value-of select="department-email"/>
          </a>
        </dd>
        <dt class="show-for-sr">Phone</dt>
        <dd>
          <a>
            <xsl:attribute name="href">
              <xsl:text>tel:</xsl:text><xsl:value-of select="translate(department-phone, '() -', '')"/>
            </xsl:attribute>
            <xsl:value-of select="department-phone"/>
          </a>
        </dd>
      </dl>
    </address>
  </xsl:template>

  <xsl:template name="add-break-tags">
     <xsl:param name="currentNode"/>
     <xsl:value-of disable-output-escaping="yes" select="hh:replaceNewlineWithBr(string($currentNode/text()))"/>
  </xsl:template>

  <xalan:component functions="replaceNewlineWithBr" prefix="hh">
    <xalan:script lang="javascript"><![CDATA[
    function replaceNewlineWithBr(str) {
        return str.replace(/\n/g, function(s, item) {
            return '<br/>';
        });
    };
    ]]></xalan:script>
  </xalan:component>
</xsl:stylesheet>