JetBrains IDE trial reset windows

extend-trial-jetbrains-windows.bat

REM Delete eval folder with licence key and options.xml which contains a reference to it
for %%I in ("WebStorm", "IntelliJ", "CLion", "Rider", "GoLand", "PhpStorm", "Resharper", "PyCharm") do (
    for /d %%a in ("%USERPROFILE%\.%%I*") do (
        rd /s /q "%%a/config/eval"
        del /q "%%a\config\options\other.xml"
    )
)

REM Delete registry key and jetbrains folder (not sure if needet but however)
rmdir /s /q "%APPDATA%\JetBrains"
reg delete "HKEY_CURRENT_USER\Software\JavaSoft" /f

It works on 31.12.2025. Thanks

@smazhevskiy From where did you download Plugin? If any working link available?

@vsachinv delete PermanentDeviceId and PermanentUserId in %APPDATA%/Jetbrains

@Seres67 Thanks but I have installed in macbook. Would it be same steps?

@smazhevskiy From where did you download Plugin? If any working link available?

PyCharm & WebStorm from the official website

@smazhevskiy From where did you download Plugin? If any working link available?

The jar file is available from when the repo was still up. You can't access the source code now after the DMCA takedown.

@SamHoque Would you be able to share the source code somehow?

I would also like to get trial reset plugin, i noticed that deleting PermanentDeviceId and PermanentUserId in appdata/roaming/jetbrains folder somehow resets trial.

Intellij Ultimate Version 2025.3.1 (.exe istaller version). I tryed the follow procedure when I have still 16 days of trial.

1. When the IDE is open you must go to Manage License and:

   • On the left menu under IDE:
     • Select IntelliJ -> Deactivate Subscription
   • On the left menu under Paid Plugins:
     • Select each Plugin -> Remove License

2. The point number 1 required to restart the IDE. Restart it and shutdown again.

3. In the folder /AppData/Roaming/JetBrains/ remove the files PermanentUserId and PermanentDeviceId (no need to remove other.xml).

4. Create new mail

5. Open your ide go to Trials and Login with new mail (you will be ask to create new account).

You'll have 30 days again.

sorry is a little bit more complex:

in [user]/AppData/Roaming I erase completely the folder JetBrains

on regedit I remove HKEY_CURRENT_USER\Software\JavaSoft\Prefs\JetBrains

This will work on latest version but remove all the configuration! Pay attention

Does anyone know how to do it on macos?

working for Arch Linux!!!

#!/bin/bash

products=("WebStorm" "IntelliJIdea" "CLion" "Rider" "GoLand" "PhpStorm" "PyCharm")

for product in "${products[@]}"; do
    find ~/.config/JetBrains/ -maxdepth 1 -type d -name "${product}*" -exec rm -rf {}/eval \;
    
    find ~/.config/JetBrains/ -maxdepth 1 -type d -name "${product}*" -exec rm -f {}/options/other.xml \;
done

jetbrains_dirs=(
    ~/.cache/JetBrains
    ~/.local/share/JetBrains
    ~/.java/.userPrefs/jetbrains
    ~/.java/.userPrefs/prefs.xml
)

for dir in "${jetbrains_dirs[@]}"; do
    if [ -e "$dir" ]; then
        rm -rf "$dir"
    fi
done

find ~/ -type d -name ".JetBrains" -exec rm -rf {} + 2>/dev/null
find ~/ -type d -name ".idea" -exec rm -rf {} + 2>/dev/null

echo "Activated succesfull"

this works but also uninstalls all your plugins and reset your settings etc.
is there any way to keep plugins and other settings?
maybe not remove all of the cache?

UPDATE: No idea what happened but seems like pycharm is now crashing for some reason
UPDATE: After deleting the entire .config/JetBrains/PyCharm* it's working now
UPDATE: It only works for like one or two time then it crashes again. I think PyCharm is bugged on linuxmint?

How to handle it on macOS?

How to handle it on macOS?

Use this, i tested it on IntelliJ 2025.3
https://github.com/garyjuano/jetbrains-reset-trial-evaluation-mac

I created a cmd script for windows. Download the file and change extension to .cmd

Tested with 2025 and 2026 IDE versions, works fine.

我创建了一个适用于 Windows 的 cmd 脚本。下载该文件并将扩展名更改为 .cmd。

已使用 2025 和 2026 版本 IDE 进行测试，运行良好。
can you share with me ?

@JimAlex927
Let me post it here as code block:

Click to expand

@echo off
REM Reset JetBrains IDE trial period
REM Run as administrator if registry deletion requires it

setlocal

echo.
echo === JetBrains Trial Reset ===
echo Removes evaluation keys, evlsprt entries, license traces,
echo device/user identity files, and registry keys.
echo.
echo TIP: Close all JetBrains IDEs before proceeding.
echo.
echo.
echo ### Information ###
echo Custom JetBrains config path is the parent directory that contains product folders.
echo Examples:
echo   C:\Soft\Develop\JetBrains\AppData
echo   (which contains .JetBrains.Rider-2026.1.win\config\, etc.)
echo.
set /p "CUSTOM_PATH=Enter custom JetBrains config path (or press Enter for defaults): "

set "PRODUCTS=IntelliJIdea WebStorm DataGrip PhpStorm CLion PyCharm GoLand RubyMine Rider ReSharper"

if not "%CUSTOM_PATH%"=="" (
  REM --- Custom path mode ---
  echo.
  echo Using custom path: %CUSTOM_PATH%
  echo.

  REM Scan for any product-matching subdirectories under the custom path
  for /d %%D in ("%CUSTOM_PATH%\*") do (
    for %%P in (%PRODUCTS%) do (
      echo %%~nxD | findstr /i "%%P" >nul 2>&1
      if not errorlevel 1 (
        echo Resetting trial period in: %%D
        call :cleanProductDir "%%D"
        echo.
      )
    )
  )
) else (
  REM --- Default paths mode ---
  echo.
  echo Using default paths.
  echo.

  for %%P in (%PRODUCTS%) do (
    echo Resetting trial period for %%P

    REM --- Old-style paths: %USERPROFILE%\.Product*\config\ ---
    for /d %%D in ("%USERPROFILE%\.%%P*") do (
      call :cleanProductDir "%%D"
    )

    REM --- New-style paths: %APPDATA%\JetBrains\Product*\ ---
    for /d %%D in ("%APPDATA%\JetBrains\%%P*") do (
      call :cleanProductDir "%%D"
    )

    echo.
  )
)

REM --- Clean shared identity files in %APPDATA%\JetBrains\ ---
echo Cleaning shared JetBrains identity files...
for %%F in (PermanentUserId PermanentDeviceId bl crl region feature_usage_event_log_salt) do (
  if exist "%APPDATA%\JetBrains\%%F" (
    echo   removing: %APPDATA%\JetBrains\%%F
    del /f /q "%APPDATA%\JetBrains\%%F"
  )
)

REM Also clean identity files from custom path if provided
if not "%CUSTOM_PATH%"=="" (
  for %%F in (PermanentUserId PermanentDeviceId bl crl region feature_usage_event_log_salt) do (
    if exist "%CUSTOM_PATH%\%%F" (
      echo   removing: %CUSTOM_PATH%\%%F
      del /f /q "%CUSTOM_PATH%\%%F"
    )
  )
)

REM --- Remove Java preferences registry key ---
reg query "HKCU\Software\JavaSoft" >nul 2>&1
if not errorlevel 1 (
  echo Removing registry key: HKCU\Software\JavaSoft
  reg delete "HKCU\Software\JavaSoft" /f >nul 2>&1
)

echo.
echo Done. Enjoy !

echo.
pause

endlocal
exit /b

REM ============================================================
REM Subroutine: clean a single product directory
REM Handles both layouts (with and without config\ subfolder)
REM ============================================================
:cleanProductDir
set "DIR=%~1"

REM --- eval directories ---
if exist "%DIR%\config\eval" (
  echo   removing eval dir: %DIR%\config\eval
  rd /s /q "%DIR%\config\eval"
)
if exist "%DIR%\eval" (
  echo   removing eval dir: %DIR%\eval
  rd /s /q "%DIR%\eval"
)

REM --- evlsprt entries in other.xml ---
if exist "%DIR%\config\options\other.xml" (
  echo   cleaning evlsprt from: %DIR%\config\options\other.xml
  findstr /v /i "evlsprt" "%DIR%\config\options\other.xml" > "%DIR%\config\options\other.xml.tmp"
  move /y "%DIR%\config\options\other.xml.tmp" "%DIR%\config\options\other.xml" > nul
)
if exist "%DIR%\options\other.xml" (
  echo   cleaning evlsprt from: %DIR%\options\other.xml
  findstr /v /i "evlsprt" "%DIR%\options\other.xml" > "%DIR%\options\other.xml.tmp"
  move /y "%DIR%\options\other.xml.tmp" "%DIR%\options\other.xml" > nul
)

REM --- evlsprt entries in options.xml (some versions use this instead) ---
if exist "%DIR%\config\options\options.xml" (
  findstr /i "evlsprt" "%DIR%\config\options\options.xml" >nul 2>&1
  if not errorlevel 1 (
    echo   cleaning evlsprt from: %DIR%\config\options\options.xml
    findstr /v /i "evlsprt" "%DIR%\config\options\options.xml" > "%DIR%\config\options\options.xml.tmp"
    move /y "%DIR%\config\options\options.xml.tmp" "%DIR%\config\options\options.xml" > nul
  )
)
if exist "%DIR%\options\options.xml" (
  findstr /i "evlsprt" "%DIR%\options\options.xml" >nul 2>&1
  if not errorlevel 1 (
    echo   cleaning evlsprt from: %DIR%\options\options.xml
    findstr /v /i "evlsprt" "%DIR%\options\options.xml" > "%DIR%\options\options.xml.tmp"
    move /y "%DIR%\options\options.xml.tmp" "%DIR%\options\options.xml" > nul
  )
)

REM --- License/key files ---
if exist "%DIR%\config\*.key" (
  echo   removing key files from: %DIR%\config\
  del /f /q "%DIR%\config\*.key"
)
if exist "%DIR%\*.key" (
  echo   removing key files from: %DIR%\
  del /f /q "%DIR%\*.key"
)
if exist "%DIR%\config\*.license" (
  echo   removing license files from: %DIR%\config\
  del /f /q "%DIR%\config\*.license"
)
if exist "%DIR%\*.license" (
  echo   removing license files from: %DIR%\
  del /f /q "%DIR%\*.license"
)

REM --- License trace storage ---
if exist "%DIR%\config\options\trace_license_storage.xml" (
  echo   removing: %DIR%\config\options\trace_license_storage.xml
  del /f /q "%DIR%\config\options\trace_license_storage.xml"
)
if exist "%DIR%\options\trace_license_storage.xml" (
  echo   removing: %DIR%\options\trace_license_storage.xml
  del /f /q "%DIR%\options\trace_license_storage.xml"
)

exit /b

Apart from reset trial approach I also could activate JetBrains using jetbra jar file.
I can share the instructions if needed.

Cannot activate the latest GoLand with jetbra file (251031) on MacOS 26. I added string to vmoptions, but now app is crashed. Can anyone provide instructions?

@v1ptyoz
Here is md file with instructions:

Click to expand

Installing the IDE

Download and install the latest IDE version

As of July 1, 2024, JetBrains restricted downloads of its products for users from Russia and Belarus. Neither the official website nor JetBrains Toolbox works directly.

Workarounds:

1. Use a VPN and download from the official website.
2. Download from the repository https://306.antroot.ru/jetbrains-download (no VPN required).
3. Download a pre-activated version from torrents (example: https://rutracker.org/forum/viewtopic.php?t=6812673).

Editing the hosts file

To prevent the IDE from validating the license online, you must block access to the JetBrains account server via the hosts file. This step is recommended for both activation options below.

Hosts file location

• Windows: C:\Windows\System32\drivers\etc\hosts (edit as administrator)
• Linux / macOS: /etc/hosts (edit via sudo)

Add the following lines to the end of the file

# All requests to the JetBrains account server are sent nowhere (a non-existent address).
# This blocks online license validation.
0.0.0.0 account.jetbrains.com
# The main site itself remains reachable
#0.0.0.0 www.jetbrains.com

Option 1 (pseudo-activation)

Installing the activation agent

Get the jetbra files

For 2025+ versions: see the ../jetbra/ folder next to this guide.

!!! Legacy link (may work for older versions up to 2024): Download

It contains the full set of files required for successful activation.

---

Extract the archive contents, for example to the root of drive C:

Unpacked files

---

Next, go to the scripts folder and run the appropriate script

• install-current-user.vbs — for the current Windows user
• install-all-users.vbs — for all Windows users
• install.sh — for macOS and Linux

---

On Windows you should see the following result.
Click OK.

The script may take a few seconds to run.
Press 'OK' and wait for the 'Done' window to appear!

---

Wait for the script to finish (there may be a few seconds of delay).
Click OK.

The 'Done' window

---

Result of running the script on Linux:

Done. You should log out of your system!

On Linux and macOS, a reboot is required after the script runs successfully.

Configuring VM Options

The VM Options configuration file must contain the following line:

-javaagent:C:\jetbra\ja-netfilter.jar=jetbrains

Where C:\jetbra\ja-netfilter.jar is the path to your unpacked archive.
In most cases this line is added automatically, but if it's not, add the path to ja-netfilter.jar manually, using the same pattern.

---

❓ How to locate the VM Options file

Typical files:
JetBrains\{Product}\bin\{product}.exe.vmoptions
JetBrains\{Product}\bin\jetbrains_client64.exe.vmoptions

For example:
C:\Program Files\JetBrains\JetBrains.Rider-2026.1.0.1.win\rider64.exe.vmoptions
C:\Program Files\JetBrains\JetBrains.Rider-2026.1.0.1.win\jetbrains_client64.exe.vmoptions

You can also edit it from within the IDE: Help → Edit Custom VM Options.

If the license notification prevents you from reaching the welcome screen, activate the Trial version first.

Path to the VM Options file in a JetBrains IDE

VM Options configuration file contents

License activation

Go to https://3.jetbra.in, which lists available hosts, and pick any working one

The site also has mirrors (if the original is down), find them via search.

Users recommend the hardbin.com host.

🙁 upd 2024-02-12 | Recently some hosts have been temporarily unavailable — if that happens, come back and try again later.

⚠️ On the gateway.pinata.cloud host the [ Copy to clipboard ] button is broken.

The 3.jetbra.in site

---

Pick the product you need

List of products available for activation

---

Click Copy to clipboard

Copy the activation key.

A few ready-made keys (alternative)

Rider 2025

---

In the IDE, open the license management section

Path to the license management section

---

Click Activate New License or Remove License

Select Activation Code and paste the code you copied earlier.

IDE activation

Result

You now have an activated IDE valid until September 2026.

Activated IDE

---

Paid plugins can be activated the same way from the list on 3.jetbra.in. For example, Extra Icons and Code With Me have been successfully activated.

Activated plugins

Option 2 (trial reset)

An alternative approach — periodically resetting the trial period. Doesn't require installing an activation agent or keys. Suitable if Option 1 doesn't work for some reason.

Get the script

The scripts are in the ../reset_trial/ folder next to this guide:

• reset_trial.cmd — for Windows
• reset_trial.sh — for macOS / Linux

Resetting the trial

Before running, close all JetBrains IDEs.

Windows: run reset_trial.cmd.

The script will prompt you to enter the path to your JetBrains config (if you use a non-standard location), or press Enter to use the default paths.

macOS / Linux: run reset_trial.sh in a terminal:

chmod +x reset_trial.sh
./reset_trial.sh

The script automatically removes:

• Evaluation (eval) keys for all JetBrains products
• evlsprt entries from configuration files
• License files and device identifiers
• Registry entries HKCU\Software\JavaSoft (Windows only)

Once finished, launch the IDE — the trial period will be reset.

You can repeat the reset procedure every time the trial period (30 days) expires.

There is a mirror of 3.jetbra.in, that currently available:
https://kdaiyu.com/3.jetbra.in/