02_consul.tf

variable "consul_machine_name" { default = "mgtcfgconl" }

resource "vsphere_virtual_machine" "consul" {
  count            = "3"
  name             = "${format("%v%02d%v", var.consul_machine_name, count.index + 1, var.environment)}"
  num_cpus         = "2"
  memory           = "1024"
  guest_id         = "${var.guest_id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  folder           = "${var.vm_folder}"

  network_interface {
    network_id     = "${data.vsphere_network.cpt-mgt-cfg-con.id}"
    adapter_type   = "vmxnet3"
  }

  scsi_type = "${data.vsphere_virtual_machine.template.scsi_type}"
  disk {
    label            = "disk0"
    size             = "8"
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template.id}"
    customize {
      linux_options {
        host_name = "${format("%v%02d%v", var.consul_machine_name, count.index + 1, var.environment)}"
        domain    = "${var.domain}"
        time_zone = "${var.timezone}"
      }
      dns_server_list  = "${var.dns_servers}"
      dns_suffix_list  = "${var.dns_search}"

      network_interface {}
    }
  }

  connection {
    type = "ssh"
    user = "${var.ssh_user}"
    password = "${var.ssh_pass}"
  }

  provisioner "file" {
    content     = "${data.template_file.minion.rendered}"
    destination = "/root/bootstrap.sh"
  }

  provisioner "remote-exec" {
    inline = [
      "chmod 744 /root/bootstrap.sh",
      "/root/bootstrap.sh",
      "rm -rf /root/bootstrap.sh"
    ]
  }

  depends_on = [
    "vsphere_virtual_machine.saltmaster"
  ]
}