Paste as keystrokes (macOS)

keystroke the clipboard extended.workflow

# Why?
# To paste text into windows that normally don't allow it or have access to the clipboard.
# Examples: Virtual machines that do not yet have tools installed, websites that hijack paste
#
# Extended vs Simple?
# * Includes an initial delay to allow you to change active windows
# * Adds small delay between keypresses for slower responding windows like SSH sessions
# * Better handling of numbers
# * VMWare bug fix
#
# Setup
# Apple Shortcuts app
#
# MAKE SURE YOUR CAPSLOCK IS OFF

on run
    tell application "System Events"
        delay 2 # DELAY BEFORE BEGINNING KEYPRESSES IN SECONDS
        repeat with char in (the clipboard)
            set cID to id of char

            if ((cID ≥ 48) and (cID ≤ 57)) then
                # Converts numbers to ANSI_# characters rather than ANSI_Keypad# characters
                # https://apple.stackexchange.com/a/227940
                key code {item (cID - 47) of {29, 18, 19, 20, 21, 23, 22, 26, 28, 25}}
            else if (cID = 46) then
                # Fix VMware Fusion period bug
                # https://apple.stackexchange.com/a/331574
                key code 47
            else
                keystroke char
            end if

            delay 0.5 # DELAY BETWEEEN EACH KEYPRESS IN SECONDS
        end repeat
    end tell
end run

keystroke the clipboard simple.workflow

on run
    tell application "System Events"
        keystroke (the clipboard)
    end tell
end run

@markmcjr Not sure if the regular Scripts Menu Privacy settings were different in Big Sur. I can however confirm that the following works on my 12.3.1 box (as an FYI, it is supervised in MDM, just in case that has an affect on this that I'm unaware of).

1. Open Script Editor
2. Create "New Document"
3. Paste the above script and adjust to taste
4. Save as a "Script" to ~/Library/Scripts (I name mine "Paste as Keystrokes.scpt")
5. In Script Editor Preferences ensure "Show Script in menu bar" is enabled
6. In SystemPreferences -> Security & Privacy -> Privacy add "/System/Library/CoreServices/Script Menu.app"
7. With some text in your clipboard and your cursor placed in a text field, select your script from the Script menu.
8. Watch with awe as your clipboard is typed as keystrokes
9. Be happy and be kind

And to echo @markmcjr, @sscotth I'm eternally grateful for this script. It's saved countless hours of frustration.

Hello, your method worked. Thank you. Is there a way to make it a shortcut? I do not have access to the menu bar in some fullscreen apps (Gforce NOW).

Is there a way to make it a shortcut? I do not have access to the menu bar in some fullscreen apps (Gforce NOW).

@xorwin Not sure if you mean "Keyboard" shortcut, but I'm not sure if you can with the Script Editor method. You can with the original Services method.

However, if you have the the new Apple Shortcuts app, it works the best. It gives you the services menu option, global menu bar (Script), and the ability to use a keyboard shortcut. You don't even need to dive into the Keyboard system preferences to setup the shortcut. Bonus points for the person who integrates their hue lights during the action.

Allow both Shortcuts.app and siriactionsd in System Preferences > Security & Privacy > Privacy > Accessibility and it should work globally

I found I needed to add an additional Conversion for the ".", as vmware fusion would not accept URLs that had a period/decimal.

                set cID to id of char
		if ((cID ≥ 48) and (cID ≤ 57)) then
			key code {item (cID - 47) of {29, 18, 19, 20, 21, 23, 22, 26, 28, 25}}
                # convert decimal from keypad to ANSI
	        else if (cID = 46) then
		        key code 47		
                 else
			# Removed incorrect line key code cID ##
                         keystroke char

		end if

@Dream-Cypher Are you sure key code cID is what you meant? cID is the ascii character code, and key code uses a different scheme.

Some old references to the bug, nothing official posted from VMware

https://apple.stackexchange.com/questions/322008/cannot-print-period-from-simple-applescript-to-vmware-fusion-virtual-machi

https://apple.stackexchange.com/questions/142986/applescript-keystroke-ignoring-numbers

Are you sure key code cID is what you meant? cID is the ascii character code, and key code uses a different scheme.

Nope... good catch! I entered the wrong line when I posted the comment. I did have "keystroke char" in my local copy.

Thanks,
Dave

TYSM!! worked for me!

With VMWare Fusion, I also had issues with grave, tilde, and pipe (was being received as keyCodes 193, Shift+193, and Shift+255, respectively):

else if (cID = 96) then
    # Fix grave (`)
    key code 50
else if (cID = 126) then
    # Fix tilde (~)
    key code 50 using {shift down}
else if (cID = 124) then
    # Fix pipe (|)
    key code 42 using {shift down}

👍

The equals '=' key doesn't work on Parallels desktop. Any idea on how to fix it ?

@SHREYAS-KS-CS104 if you load https://w3c.github.io/uievents/tools/key-event-viewer.html inside parallels, and then use this to type equals, what keyDown events do you see?

Any chance one of you could develop a Mac app to paste clipboard as keystrokes entry? I use this daily where text windows don’t allow pasting and it’s critical for my daily work but lately I’ve been getting error messages at times trying in Chrome and Safari. If this stops working entirely it would be a severe blow to my daily work so I would gladly pay for a reliable and easily installed app.

please help!!

Any chance one of you could develop a Mac app to paste clipboard as keystrokes entry? I use this daily where text windows don’t allow pasting and it’s critical for my daily work but lately I’ve been getting error messages at times trying in Chrome and Safari. If this stops working entirely it would be a severe blow to my daily work so I would gladly pay for a reliable and easily installed app.

please help!!

I found a Golang script, with a little modification:

package main

import (
	"github.com/GuoFlight/gkeybd"
	"golang.design/x/clipboard"
)

func main() {
	err := clipboard.Init()
	if err != nil {
		panic(err)
	}
	content := string(clipboard.Read(clipboard.FmtText))
	err = gkeybd.TypeStr(content)
	if err != nil {
		panic(err)
	}
}

and after compiling it, with iCanHazShortcut, I can finally bind the paste key to the keyboard, it works like a charm.

Warning: need to change #import <Foundation/Foundation.h> in vendor/github.com/micmonay/keybd_event/keybd_darwin.go to #import <Cocoa/Cocoa.h> in macOS when compiling.

@PeetMcK @markmcjr

Not sure if the regular Scripts Menu Privacy settings were different in Big Sur. I can however confirm that the following works on my 12.3.1 box (as an FYI, it is supervised in MDM, just in case that has an affect on this that I'm unaware of).

1. ...
...
5. In Script Editor Preferences ensure ...
6. In SystemPreferences -> Security & Privacy -> Accessibility add ...
...

I think think this way of embedding into MacOS menu has more merit than via "Quick Action" method. In the latter case you have to give any app that initiates the Quick Action permissions to control the computer, which is inconvenient and security threat. In the way mentioned by PeetKcK you only have to perform one time a few actions for only one Apple Supplied MacOS App.

Thanks @sscotth for creating this script and others for making it more user-friendly !