Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
SELECT ?agent
WHERE
{ { ?r dct:creator _:b0 .
_:b0 rdfs:member ?agent
}
UNION
{ ?r dct:creator ?agent
FILTER NOT EXISTS {?agent rdfs:member ?member }
}
}
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
SELECT ?name
WHERE
{ { ?agent foaf:name ?name }
UNION
{ ?agent vcard:fn ?name }
UNION
{ ?agent vcard:FN ?name }
UNION
{ ?agent rdfs:label ?name }
UNION
{ { ?agent vcard:n ?n }
UNION
{ ?agent vcard:hasName ?n }
?n vcard:family-name ?family .
?n vcard:given-name ?given
BIND(concat(?given, " ", ?family) AS ?name)
}
UNION
{ ?agent foaf:givenName ?given .
?agent foaf:familyName ?family
BIND(concat(?given, " ", ?family) AS ?name)
}
UNION
{ ?agent foaf:firstName ?given .
?agent foaf:surname ?family
BIND(concat(?given, " ", ?family) AS ?name)
}
}
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>
SELECT ?mbox
WHERE
{ { ?agent foaf:mbox ?mbox }
UNION
{ ?agent vcard:hasEmail ?mbox }
UNION
{ ?agent vcard:email ?email
BIND(iri(concat("mbox:", ?email)) AS ?mbox)
}
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.