Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
SheepShaver wrapper source - remove lame, confusing error
-- Self-contained SheepShaver Wrapper
-- Version 5.93 - 27 February 2012
-- Script by Edward Mendelson http://wpdos.org
-- DEFAULT SCREEN SIZE
-- feel free to change these settings from 896 x 672
property defaultWidth : 896
property defaultHeight : 672
-- USE DEFAULT SCREEN SIZE OR CALCULATE PORTRAIT OR LANDSCAPE SIZE
-- the default SheepShaver Wrapper size is 896 x 672; however,
-- if you want the SheepShaver Wrapper screen size to be calculated
-- as a proportion of your Mac's screen size, change 0 to 1 or 2 below
-- for a calculated landscape-style layout, change 0 to 1
-- for a calculated portrait-style layout, change 0 to 2
property calculateSize : 0
-- to specify window size permanently, use the SheepShaver Preferences dialog;
-- to make a portrait-layout window that WP can fill, use width 640, height 720 (or up to 742)
-- USE HOME FOLDER (NOT USER/DOCUMENTS) AS "UNIX" FOLDER
-- by default, this script uses the user's Documents folder as the
-- SheepShaver "Unix" folder; you may prefer to use your
-- Home folder instead, although this may cause problems for
-- other AppleScripts; to use Home, change 0 to 1 below
property useHomeFolder : 0
-- never change anything below these lines!
-------------------------------------------------------------
-------------------------------------------------------------
property msgTitle : "SheepShaver Wrapper"
property reqVers : 5
property sizeList : {"1949186", "1948761", "1945746"} -- known good ROM file sizes
global forceFullScreen, defaultScreenSize
global sheepApp, sheepPath, filesFolder, macSystem, macPath
global userPath, unixPosixPath, userLibPath, userPosixPath, unixPath
global vertBound, horizBound, maxHeight, maxWidth, fullScreen
global UNIX_plist_path, presMode, ssRunning, questionIcon
global thisApp, checkKeysPosix, myUnix, vmPath, vmPosix
global extfsPath, useSelectedUnix, selectUnixFolder
global cdPosix, doCD, noCDPath, prefsPath
on open theDrop
set doCD to false
if (count of theDrop) is greater than 1 then
set dialogText to "Drop either a file named “Mac OS ROM” on a disk image of a Mac OS installation disk on me." & return & return & "Drop only one file at a time."
errorQuit(dialogText)
end if
repeat with dropFile in theDrop
tell application "Finder" to set dropName to the name of dropFile
tell application "Finder" to set dropExt to the name extension of dropFile
if dropName is "Mac OS ROM" then
set dropFile to dropFile as string
tell application "Finder"
set thisPosix to POSIX path of (dropFile as alias)
set romSize to size of (dropFile as alias) as string
-- display dialog romSize
end tell
if romSize is in sizeList then
else
tell me to activate
display dialog "The file that you dropped is not one of the ROM files that has been tested with this system." & return & return & "I will install it in the correct location, but I cannot guarantee that SheepShaver will start up." & return & return & "If you encounter any problems, please find a different ROM file and drop it on me." & return & return & "You do not need to remove the ROM file that causes problems. Simply drop a new one on me." buttons {"Cancel", "OK"} default button 2 with title msgTitle giving up after 20
if button returned of result is "Cancel" then
error number -128
end if
end if
set thisApp to path to me as text
set romFilePath to (thisApp & "Contents:Resources:Files:MacOS.sheepvm:Mac OS ROM")
set romFilePosix to quoted form of (POSIX path of romFilePath)
try
do shell script "cp " & quoted form of thisPosix & space & romFilePosix
on error
set dialogText to "Could not copy ROM file to this application. Sorry."
errorQuit(dialogText)
end try
tell me to activate
display dialog "ROM file copied successfully." & return & return & "Now install Mac OS according to the instructions." buttons {"OK"} with title msgTitle giving up after 10
error number -128
else
set extList to {"cdr", "iso", "dmg", "dsk", "img", "toast", "img"}
if dropExt is in extList then
my installCD(dropFile, dropExt)
else
set dialogText to "Please drop either a file named “Mac OS ROM” or a Mac OS installation disk image on me." & return & return & "Do not drop any other kind of file."
errorQuit(dialogText)
end if
end if
end repeat
end open
on run
set doCD to false
doBasics()
runVM()
error number -128
end run
-------------------------------------------------------------
-- shared routines
on doBasics()
-- USE QUASI-FULLSCREEN MODE
-- to make SheepShaver Wrapper run in a quasi-fullscreen mode, use the SheepShaver
-- preferences dialog and set mode to fullscreen, not window
-- or, in preferences, set both height and width to 0
-- alternatively, to force fullscreen mode, change 0 to 1 below
-- or hold down Command key when launching this application
-- Warning: this option hides the dock and menu bar when this app runs
-- NOTE THAT SETTING "forceFullScreen : 1" OVERRIDES "calculateSize : 1 or 2"
set forceFullScreen to 0
-- RESTORE DEFAULT SCREEN SIZE 896 x 672
-- to restore default screen size change 0 to 1
-- or hold down Option key when launching this application
set defaultScreenSize to 0
checkHostSystem()
screenDimension()
getMyName()
setupPaths()
writePrefs()
end doBasics
-------------------------------------------------------------
-- starting subroutines
-- not used yet
on processRunning(processName)
return (do shell script "ps axc") contains processName
end processRunning
on checkHostSystem()
-- Running on Leopard or later?
set Leopard to 0
set sysVers to ((system attribute "sysv") mod 4096 div 16)
if sysVers < reqVers then
set dialogText to "This application runs under OS X 10." & reqVers & " or later, and you seem to have an earlier version of OS X."
errorQuit(dialogText)
end if
if sysVers is 5 then set Leopard to 1
-- is SheepShaver already running?
set ssRunning to false
tell application "System Events"
try
first process whose bundle identifier is "org.wpdos.wrappedsheepshaver"
set ssRunning to true
end try
end tell
end checkHostSystem
on screenDimension()
-- change screen dimension, check for Cmd or Option key down, to set or unset full-screen
set thisApp to path to me as text
set checkKeysPath to (thisApp & "Contents:Resources:Files:checkModifierKeys")
set checkKeysPosix to quoted form of (POSIX path of checkKeysPath)
set cmdState to do shell script checkKeysPosix & space & "cmd"
set optionState to do shell script checkKeysPosix & space & "option"
set capsState to do shell script checkKeysPosix & space & "capslock"
-- CapsLock on means go to setup menu
if capsState is "1" then
repeat while capsState is "1"
tell me to activate
display dialog "Please turn off Caps Lock before proceeding." buttons {"OK"} default button 1 with title msgTitle
set capsState to "0"
set capsState to do shell script checkKeysPosix & space & "capslock"
end repeat
set extraString to return & return & "This menu appears if CapsLock is ON when the application starts."
my askforUnix(extraString)
end if
-- Cmd down means go to quasi-full-screen
if cmdState is "1" then
tell me to activate
display dialog "Set SheepShaver to open in a quasi-full-screen mode?" & return & return & "(This message appears because you held down the Command key while starting the application.)" & return & return & "If you click OK to set quasi-full-screen mode, you can return to ordinary windowed mode by holding down the Option key the next time you start the application." buttons {"OK", "Cancel"} default button 1 with title msgTitle
if button returned of the result is "Cancel" then
error number -128
else
tell application "System Events"
if UI elements enabled then
else
my setupUniversalAccess()
end if
end tell
-- if forceFullScreen is 0 then
set forceFullScreen to 1
-- else
-- set forceFullScreen to 0
-- end if
end if
end if
-- Option down means switch back to default size
if optionState is "1" then
tell me to activate
display dialog "Set SheepShaver to open in ordinary windowed mode?" & return & return & "(This message appears because you held down the Option key while starting the application.)" & return & return & "You may switch to a quasi-full-screen mode by holding down the Command key the next time you start the application." buttons {"OK", "Cancel"} default button 1 with title msgTitle
if button returned of the result is "Cancel" then
error number -128
end if
tell application "System Events"
if UI elements enabled then
else
my setupUniversalAccess()
end if
end tell
set forceFullScreen to 0
set defaultScreenSize to 1
end if
if ssRunning is false then
set horizBound to 0
set vertBound to 0
-- routines to set screen size
set dspsizes to getDspSizes()
set widthList to {}
set heightList to {}
repeat with thisItem in dspsizes
set the end of widthList to first item in thisItem as number
set the end of heightList to second item in thisItem as number
end repeat
set sortedWidths to simple_sort(widthList)
set sortedHeights to simple_sort(heightList)
set maxWidth to the first item in sortedWidths as number
set maxHeight to the first item in sortedHeights as number
if calculateSize = 1 then
set horizBound to round maxHeight * 1.12
if horizBound is greater than 1600 then
set horizBound to 1600
else if horizBound is greater than 1280 then
set horizBound to 1280
else if horizBound is greater than 1152 then
set horizBound to 1152
end if
set vertBound to round horizBound * 0.75
set vertBound to vertBound as string
set horizBound to horizBound as string
else if calculateSize = 2 then
set horizBound to round maxHeight * 0.8
if horizBound is greater than 1600 then
set horizBound to 1600
else if horizBound is greater than 1280 then
set horizBound to 1280
else if horizBound is greater than 1152 then
set horizBound to 1152
end if
set vertBound to round horizBound * 1.125
set vertBound to vertBound as string
set horizBound to horizBound as string
end if
end if
end screenDimension
on setupPaths()
set useSelectedUnix to 1
try
do shell script "ls " & quoted form of extfsPath
on error
set useSelectedUnix to 0
end try
-- use Home or Documents folder?
if useHomeFolder = 1 then
set otherUnix to path to documents folder as text
else
set otherUnix to path to home folder as text
end if
if useSelectedUnix = 1 then
my setUnixFolder()
else
if useHomeFolder = 1 then
set unixPosixPath to POSIX path of (path to home folder)
set unixPath to path to home folder as text
-- set otherUnix to path to documents folder as text
else
set unixPosixPath to POSIX path of (path to documents folder)
set unixPath to path to documents folder as text
-- set otherUnix to path to home folder as text
end if
end if
set userPath to path to home folder as text
set userLibPath to path to library folder from user domain as text
-- Set up paths in this app
set sheepApp to (path to me) & "Contents:Resources:Files:SheepShaver.app" as string
set sheepApp to sheepApp as alias
set sheepPath to (POSIX path of sheepApp)
try
set macRom to (path to me) & "Contents:Resources:Files:MacOS.sheepvm:Mac OS ROM" as string
set macRom to macRom as alias
on error
set dialogText to "Drop a New World PPC ROM image file named “Mac OS ROM” on me." & return & return & "I cannot start without this file."
errorQuit(dialogText)
end try
try
set macSystem to (path to me) & "Contents:Resources:Files:MacOS.sheepvm" as string
set macSystem to macSystem as alias
set macPath to (POSIX path of macSystem)
on error
set dialogText to "Add a self-contained sheepvm named MacOS.sheepvm to this application, in the folder Contents:Resources:Files."
errorQuit(dialogText)
end try
set questionIcon to ((path to me as text) & "Contents:Resources:Files:Question.icns") as alias
end setupPaths
on setUnixFolder()
set vmPath to (path to me) & "Contents:Resources:Files:MacOS.sheepvm" as string
set vmFile to vmPath as alias
set vmPosix to (POSIX path of vmFile) as string
set extfsPath to (vmPosix & "extfspath")
set unixPath to paragraph 1 of (read POSIX file extfsPath)
set unixPosixPath to POSIX path of file unixPath
if useHomeFolder = 1 then
set otherUnix to path to home folder as text
else
set otherUnix to path to documents folder as text
end if
end setUnixFolder
on writePrefs()
if ssRunning is false then
set prefsFile to (path to me) & "Contents:Resources:Files:MacOS.sheepvm:prefs" as string
set prefsFile to prefsFile as alias
set prefsPath to (POSIX path of prefsFile) as string
set savePath to ((POSIX path of prefsFile) & ".storage")
set tempPath to ((POSIX path of prefsFile) & ".tempfile")
set screenPath to ((POSIX path of prefsFile) & ".screen")
try
do shell script "cp " & quoted form of prefsPath & " " & quoted form of savePath
on error
set dialogText to "Problem backing up preferences file. No changes made."
end try
-- remove existing data before replacing
try
if (calculateSize is greater than 0) or (defaultScreenSize is greater than 0) then
do shell script "grep -v '^extfs\\|^screen' " & quoted form of prefsPath & " > " & quoted form of tempPath
else
do shell script "grep -v '^extfs' " & quoted form of prefsPath & " > " & quoted form of tempPath
end if
on error
set dialogText to "Problem extracting data from preference file. No changes made."
errorQuit(dialogText)
end try
-- insert replaced data
try
do shell script "echo extfs " & quoted form of unixPosixPath & ">> " & quoted form of tempPath
if defaultScreenSize is greater than 0 then
copy defaultWidth to horizBound
copy defaultHeight to vertBound
end if
if (calculateSize is greater than 0) or (defaultScreenSize is greater than 0) then
do shell script "echo screen win/" & horizBound & "/" & vertBound & " >> " & quoted form of tempPath
end if
on error
set dialogText to "Problem reading data from preference file. No changes made."
errorQuit(dialogText)
end try
try
do shell script "mv " & quoted form of tempPath & " " & quoted form of prefsPath
on error
set dialogText to "Problem creating new preferences file. No changes made."
errorQuit(dialogText)
end try
try
do shell script "rm " & quoted form of savePath
end try
-- routine for full-screen option
set fullScreen to 0
if forceFullScreen = 1 then
set fullScreen to 1
end if
set fullWidth to maxWidth as string
set fullHeight to maxHeight - 21 as string
set fullNumbers to fullWidth & "/" & fullHeight
-- did user specify "fullscreen" or 0/0 dimensions in SheepShaver prefs?
if fullScreen = 0 then
try
set fullByPrefs to true
set fullScreen to do shell script "grep -c 'dga/\\|/0/0' " & quoted form of prefsPath
on error
set fullByPrefs to false
end try
--
try
set fullByPrevious to true
set fullScreen to do shell script "grep -c '" & fullNumbers & "' " & quoted form of prefsPath
on error
set fullByPrevious to false
end try
if fullByPrefs is true then set fullScreen to 1
if fullByPrevious is true then set fullScreen to 1
end if
if fullScreen is greater than 0 then
-- set SheepShaver size to width of Mac by height minus menu line
-- set fullWidth to maxWidth as string
-- set fullHeight to maxHeight - 21 as string
try
do shell script "cp " & quoted form of prefsPath & " " & quoted form of savePath
on error
set dialogText to "Problem backing up preferences file. No changes made."
end try
try
do shell script "grep -v '^screen' " & quoted form of prefsPath & " > " & quoted form of tempPath
on error
set dialogText to "Problem reading screen size from preference file. No changes made."
errorQuit(dialogText)
end try
try
do shell script "echo screen win/" & fullWidth & "/" & fullHeight & " >> " & quoted form of tempPath
end try
try
do shell script "mv " & quoted form of tempPath & " " & quoted form of prefsPath
on error
set dialogText to "Problem writing new preferences file. No changes made."
errorQuit(dialogText)
end try
try
do shell script "rm " & quoted form of savePath
end try
-- modify info.plist so dock disapepars
set presMode to "LSUIPresentationMode"
set Mac_plist_path to (sheepPath as string) & "Contents/"
-- display dialog Mac_plist_path
tell application "Finder"
set plistFile to (Mac_plist_path & "info.plist")
if not (exists (file (Mac_plist_path & "original.plist"))) then
try
do shell script "cp " & quoted form of POSIX path of plistFile & space & quoted form of POSIX path of (Mac_plist_path & "original.plist")
on error
tell me to activate
display dialog "Problem here."
end try
end if
end tell
set UNIX_plist_path to quoted form of POSIX path of (Mac_plist_path & "info")
set script_text to "defaults write " & UNIX_plist_path & space & presMode & space & "-int" & space & "4"
try
do shell script script_text
on error
set script_text to "defaults write " & UNIX_plist_path & space & presMode & space & "-int" & space & "1"
try
do shell script script_text
on error
tell me to activate
display dialog "Error writing SheepShaver defaults for enclosed SheepShaver virtual machine." buttons {"OK"} default button 1 with icon stop giving up after 5
end try
end try
end if
if doCD is true then
set noCDPath to (prefsPath & ".noCD")
set bootCDPath to (prefsPath & ".bootCD")
set tempCDFile to (prefsPath & ".tempCD")
try
do shell script "cp " & quoted form of prefsPath & space & quoted form of noCDPath
on error
set dialogText to "Problem backing up preferences file. No changes made."
errorQuit(dialogText)
end try
try
do shell script "echo " & quoted form of ("disk " & cdPosix) & space & ">" & space & quoted form of tempCDFile
do shell script "cat " & quoted form of prefsPath & space & ">>" & space & quoted form of tempCDFile
on error
do shell script "mv " & quoted form of noCDPath & space & quoted form of prefsPath
set dialogText to "Problem creating preferences file. No changes made."
errorQuit(dialogText)
end try
do shell script "mv " & quoted form of tempCDFile & space & quoted form of prefsPath
end if
end if
end writePrefs
on runVM()
-- now to run the program
if ssRunning is true then
do shell script "open -a" & space & quoted form of sheepPath
else
do shell script "open -a" & space & quoted form of sheepPath & space & quoted form of macPath
-- if full screen, nudge window to top of screen
if fullScreen is greater than 0 then
tell application "System Events"
repeat until (process "SheepShaver" exists)
delay 0.1
end repeat
tell process "SheepShaver"
repeat until window 1 exists
delay 0.1
end repeat
end tell
delay 0.7
tell process "SheepShaver"
tell window 1
set position to {0, 0}
end tell
end tell
end tell
delay 0.5
-- restore original info.plist settings
set script_text to "defaults write " & UNIX_plist_path & space & presMode & space & "-int" & space & "1"
try
do shell script script_text
--display dialog "Set SheepShaver to hide dock." with icon caution giving up after 5
on error
tell me to activate
display dialog "Error writing SheepShaver defaults for enclosed SheepShaver virtual machine." buttons {"OK"} default button 1 with icon stop giving up after 5
end try
end if
end if
if doCD is true then
delay 1
try
do shell script "mv " & quoted form of noCDPath & space & quoted form of prefsPath
on error
display dialog "couldn't move the file"
end try
end if
end runVM
-------------------------------------------------------------
-- subroutines
on getDspSizes()
set dspsizes to {}
set toolpath to ((path to me) as Unicode text) & "Contents:Resources:Files:dspsizes"
set command to (quoted form of POSIX path of toolpath)
set output to paragraphs of (do shell script command)
repeat with dspinfo in output
set dspsizes to dspsizes & {({word 1, word 3} of dspinfo)}
end repeat
-- display dialog ({word 1} of dspinfo as string) & " x " & ({word 3} of dspinfo as string)
-- {{"1440", "900"}, {"800", "600"}}
end getDspSizes
on simple_sort(my_list)
set the index_list to {}
set the sorted_list to {}
repeat (the number of items in my_list) times
set the low_item to ""
repeat with i from 1 to (number of items in my_list)
if i is not in the index_list then
set this_item to item i of my_list as text
if the low_item is "" then
set the low_item to this_item
set the low_item_index to i
else if this_item comes before the low_item then
set the low_item to this_item
set the low_item_index to i
end if
end if
end repeat
set the end of sorted_list to the low_item
set the end of the index_list to the low_item_index
end repeat
return the sorted_list
end simple_sort
on errorQuit(dialogText) -- Fatal error, quitting script
tell me to activate
display dialog dialogText buttons {"OK"} default button 1 with icon stop with title msgTitle giving up after 20
error number -128
end errorQuit
on cautionQuit(dialogText) -- Only a caution, possibly quit?
tell me to activate
display dialog dialogText buttons {"Continue?", "Quit"} default button 2 with icon caution with title msgTitle
set userChoice to button returned of result
if userChoice = "Quit" then
error number -128
end if
end cautionQuit
on getMyName()
-- in case we need to use selected unix folder
set vmPath to (path to me) & "Contents:Resources:Files:MacOS.sheepvm" as string
set vmFile to vmPath as alias
set vmPosix to (POSIX path of vmFile) as string
set extfsPath to (vmPosix & "extfspath")
tell application "System Events" to set myName to name of (get properties of (path to me))
set myName to text 1 thru -5 of myName
if myName contains "setup" then
set extraString to return & return & "Remove “Setup” from my name to hide this menu next time"
my askforUnix(extraString)
end if
end getMyName
on askforUnix(extraString)
tell me to activate
display dialog "Select an OS X folder to use as the “Unix” folder in SheepShaver." & extraString buttons {"Documents folder", "Home folder", "Choose another…"} default button 1 with title msgTitle
if button returned of result is "Documents folder" then
set useHomeFolder to 0
try
do shell script "rm " & quoted form of extfsPath
end try
else if button returned of result is "Home folder" then
set useHomeFolder to 1
try
do shell script "rm " & quoted form of extfsPath
end try
else if button returned of result is "Choose another…" then
set myUnix to choose folder with prompt "Select a folder for the “Unix” folder in SheepShaver and click Choose:"
set unixPath to myUnix as text
do shell script "echo " & unixPath & " > " & quoted form of extfsPath
end if
end askforUnix
on setupUniversalAccess()
tell application "System Events"
if UI elements enabled then
else
-- GUI scripting not enabled; display an alert
tell me to activate
display dialog "To switch to and from a custom full-screen size, I must turn on the OS X feature “Enable access for assistive devices”." & return & return & "May I turn on this feature?" & return & return & "If you answer Yes, OS X will prompt you for a password." buttons {"No", "Yes"} default button 2 with icon caution with title msgTitle
set enableGUI to button returned of result
if enableGUI is "No" then
display dialog "You may enable the required feature in System Preferences, in the Universal Access pane, by adding a checkbox next to “Enable access for assistive devices”." & return & return & "This application will now close." buttons {"OK"} default button 1 with icon caution with title msgTitle
quit
error number -128
else
tell application "System Events" to set UI elements enabled to true
end if
end if
end tell
delay 1
end setupUniversalAccess
on installCD(dropFile, dropExt)
try
set macRom to (path to me) & "Contents:Resources:Files:MacOS.sheepvm:Mac OS ROM" as string
set macRom to macRom as alias
on error
set dialogText to "Drop a New World PPC ROM image file named “Mac OS ROM” on me before installing Mac OS." & return & return & "I cannot start without this file."
errorQuit(dialogText)
end try
tell application "Finder"
if locked of (dropFile as alias) is true then
else if owner privileges of (dropFile as alias) is read only then
else
display dialog "The disk image file must be locked in the Finder or the Mac OS will not install. Shall I lock the file for you?" buttons {"Cancel", "OK"} default button 2 with title msgTitle
if button returned of the result is "Cancel" then
error number -128
end if
set locked of (dropFile as alias) to true
end if
set cdPosix to POSIX path of (dropFile as alias)
if dropExt is "cdr" then
set formatWarn to ""
set imageWarn to "different image file,"
else
set formatWarn to "Image files with the extension “" & dropExt & "” may not boot in SheepShaver." & return & return
set imageWarn to "disk image made by Disk Utility in DVD/CD Format, with the extension “cdr”,"
end if
display dialog "I will try to boot SheepShaver from the disk image file that you have dropped on me." & return & return & formatWarn & "If I succeed in booting from this disk image, install Mac OS from the disk image to the emulated hard disk in SheepShaver. Then quit SheepShaver entirely." & return & return & "If I fail to boot from this disk image, press Control-Esc to quit SheepShaver. Then try again with a " & imageWarn & " or mount a physical CD in OS X before starting me." & return & return & "The next time I start up, I will not attempt to boot from this disk image." buttons {"Cancel", "OK"} default button 2 with title msgTitle giving up after 20
if button returned of result is "Cancel" then
error number -128
end if
end tell
set doCD to true
doBasics()
runVM()
error number -128
end installCD
# sha1's of fixed download
# https://dl.dropbox.com/sh/fs60td2cpbv63w0/qXNO3PBh68/SheepShaver%20Wrapper%20fixed.zip (sha1: d7b21016a65a44b6e917ac3a32a9c62d49ddb8b9)
20edfd6b54d5d3fb230fb5fcabc49ddcdb94a930 ./Contents/_CodeSignature/CodeResources
b50d42254dd8e376c213dcc81c95cb9b7c929d87 ./Contents/Info.plist
77db19d80e3f9694e906ac96ecbcf8de7ad561ac ./Contents/MacOS/droplet
04742a1bf628b735f4680f5195a8bb4b747090cc ./Contents/PkgInfo
9c3ae103d0891c04b374bbbdfc2abb7c211258b9 ./Contents/Resources/description.rtfd/TXT.rtf
3ff7ce07b481a629f44ff0f4522affdee84f59b1 ./Contents/Resources/droplet.icns
bceadb5ece62ff8b2754ae4dc2ce74eade571e0d ./Contents/Resources/droplet.rsrc
7fb457bfb7082bbd6f1c27871ad9bad8ce1a65ab ./Contents/Resources/Files/checkModifierKeys
ea3555d331366d3f5c7a580bcfcb6e6082043a61 ./Contents/Resources/Files/dspsizes
adc83b19e793491b1c6ea0fd8b46cd9f32e592fc ./Contents/Resources/Files/MacOS.sheepvm/!! Add the Mac OS ROM file to this folder !!
6a8e130aba53f7619ee8ba890c7697d168123188 ./Contents/Resources/Files/MacOS.sheepvm/.LSOverride
da39a3ee5e6b4b0d3255bfef95601890afd80709 ./Contents/Resources/Files/MacOS.sheepvm/Icon
82effcbb6df7eb02774e12d0c99d7dd2ecf3d62e ./Contents/Resources/Files/MacOS.sheepvm/keycodes
b57f7bbcb528080f9ea1c338d77227caf10ab49b ./Contents/Resources/Files/MacOS.sheepvm/nvram
da39a3ee5e6b4b0d3255bfef95601890afd80709 ./Contents/Resources/Files/MacOS.sheepvm/ppc.log
38993ab8a7d7cf5b84ae93f6ab1cf4c16b17e906 ./Contents/Resources/Files/MacOS.sheepvm/prefs
093b2c5f93e56c5f0d708f9c39b00c9a4cb33326 ./Contents/Resources/Files/MacOS.sheepvm/SheepShaver512.dsk
8220a4bdb82c33e1ddf578ab47cb0adf1f01d030 ./Contents/Resources/Files/Question.icns
93080edef8f7c52a2d97dcc70d4ae2a8d06c91f3 ./Contents/Resources/Files/SheepShaver.app/Contents/_CodeSignature/CodeResources
bd084a8ef3c7f7572ef0b0cb05cc0b63c4e31476 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/_CodeSignature/CodeResources
f7c851dc0ea48d9050ac2ddd3526cffbc1c8ef64 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/begin_code.h
871fa8c8500895e7e5a115581a5e62119b0a01b8 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/close_code.h
2fce7c02a2e5effc68015606b7b0d6776234aa32 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL.h
c85ace75862403faa9d3221e466cb28326f96164 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_active.h
39f81d7dcc4b6efcd30d35977fc9fe56d23fd4d2 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_audio.h
854d680cb01bc066881ab50aca2cc1fddb2c0e94 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_byteorder.h
81ed8fde08ec202d617906c186347094cf878fe1 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_cdrom.h
079dd604650f1214ab06a134069405e7258c45b6 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config.h
1a15b104209b1ed7c8a36f27a4aa6baf78b9adb3 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config_dreamcast.h
726aa05376be2157f47dc5e5a5a1b68e276b8a50 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config_macos.h
6404695079916b8229c3a18227478e1a140fc95d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config_macosx.h
070aca7628c0f299fae730151426a8b577f59db8 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config_os2.h
0b88a9bf5d085a53e54396c14b19f22e5c9fa8aa ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_config_win32.h
caca76a8d3235492d9301df6e482723f7c744bd3 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_copying.h
6d2b061203ed2351b01369bcf1e25057e6a3a885 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_cpuinfo.h
654e3661f86f8348e7e9199b27623db6ad61d4ed ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_endian.h
4810b88bc7254b06e74abd249ed3bb049ef5a5e3 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_error.h
b1d039afea5789b48a5871460f9917839cb2082d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_events.h
46ab67664062168fc2060a8ede0cc531b99ecb9d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_getenv.h
1ae166436696b5ab01006d95f807519ae1687b8f ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_joystick.h
6df0f02b8f19329d15efa622a1148de8f6523b95 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_keyboard.h
0264a981d4094c81ce8bbae74afab6803e07753d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_keysym.h
cf9a8cd6f890a82084f29f3fc664b35c1e5750e8 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_loadso.h
5409ec4ab32a4051c852abd6173e249d90772854 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_main.h
072f13d5fcb89e02f1f2bfcfc9be5f260df5843d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_mouse.h
f1b634f6629f7862809538f4a27476733315d53a ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_mutex.h
219f7023c75471e3d2c1866da8353d1c5e9dbfe8 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_name.h
962a5d72c7fe7e034498d5a9813accc5c2331f89 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_opengl.h
bf175e2dd5052623a7b33e8bfe56798a0e6950c2 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_platform.h
2068a93d8cf11d3f4884e797e839a112b4ba176d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_quit.h
7c7ed68fd19537b853785a033c9b854111b3c171 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_rwops.h
5a89a4830c183e82d39643e0d9f0927acfa4f0dc ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_stdinc.h
f9cdea3a831b31625dd329d5318ce4497493162e ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_syswm.h
e4618da5f2843439480b487a741c0812c93fe5fd ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_thread.h
a4721f35e0dd515a2e6081763fd4740f6145ccf2 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_timer.h
53b720cfea788400298c5e896fe3ff2aa5a03ae5 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_types.h
cf27d0146d6caedc1b344053feded5c18a38641d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_version.h
03b12ebea6764f227cb5a924769c4cc87dd84187 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Headers/SDL_video.h
55251e45764cf23bee0eca8bac8657a68f35556d ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Resources/Info.plist
28faa1acc5dfcb7e561c3ab294f32eecbca83bfb ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/Resources/SDLMain.nib/objects.nib
6f3d39b57f2e7984d224b8f0aaef77e2cef86cd6 ./Contents/Resources/Files/SheepShaver.app/Contents/Frameworks/SDL.framework/Versions/A/SDL
a3bc926b8bbc5037d811587f07776fc322439a1b ./Contents/Resources/Files/SheepShaver.app/Contents/Info.plist
7f2a3d6c8dd0b902bd6a6ca15fb4e0ebe47e7e73 ./Contents/Resources/Files/SheepShaver.app/Contents/MacOS/SheepShaver
9f9eea0cfe2d65f2c3d6b092e375b40782d08f31 ./Contents/Resources/Files/SheepShaver.app/Contents/PkgInfo
cd43b940b618cc49135ddca757ae97b4adc6715a ./Contents/Resources/Files/SheepShaver.app/Contents/Resources/English.lproj/VMSettingsWindow.nib
83257903a0ce614d9bd48b0c1dedc996bce0b89c ./Contents/Resources/Files/SheepShaver.app/Contents/Resources/HappyMac.icns
3ff7ce07b481a629f44ff0f4522affdee84f59b1 ./Contents/Resources/Files/SheepShaver.app/Contents/Resources/SheepShaver.icns
cff0af9d395ea930bfb558ea0db66e39b144bb4f ./Contents/Resources/Scripts/main.scpt
da39a3ee5e6b4b0d3255bfef95601890afd80709 ./Icon
@steakknife

This comment has been minimized.

Copy link
Owner Author

steakknife commented Jan 31, 2013

@steakknife

This comment has been minimized.

@steakknife

This comment has been minimized.

Copy link
Owner Author

steakknife commented Jan 31, 2013

And the SheepShaver Wrapper with the fix can be

download directly HERE

hosted by me

@steakknife

This comment has been minimized.

Copy link
Owner Author

steakknife commented Jan 31, 2013

I've verified it works. Darn no TDD test cases here. 👍

@steakknife

This comment has been minimized.

Copy link
Owner Author

steakknife commented Jan 31, 2013

(OLD, deprecated.... use https://github.com/kallisti5/sheepshear )

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.