apex-mle-get-libraries.sql

declare
    type module_t is table of varchar2(100) index by varchar2(100);
    l_modules   module_t := module_t();
    l_module    varchar2(100);
    l_code      clob;
begin
    /* store the name and location of each library that is to be imported */
    l_modules('qrcode')     := 'https://cdnjs.cloudflare.com/ajax/libs/qrcode-generator/1.4.4/qrcode.min.js';
    l_modules('validator')  := 'https://cdnjs.cloudflare.com/ajax/libs/validator/13.5.2/validator.min.js';
    l_modules('marked')     := 'https://cdnjs.cloudflare.com/ajax/libs/marked/1.2.9/marked.min.js';
    
    delete from javascript_modules;
    
    l_module := l_modules.first;
    
    /* loop through all records, GET each library and save it in the javascript_modules table */
    while l_module is not null
    loop
        l_code := apex_web_service.make_rest_request
            ( p_url         => l_modules(l_module)
            , p_http_method => 'GET'
            );

        insert
          into javascript_modules
        values (l_module, l_code);

        l_module := l_modules.next(l_module);
    end loop;
    
    commit;
end;
/