Lasso code that demonstrates the use of sessions and cookies

session_cookie.lasso

[
!var_defined('fruit') ? var(fruit) = map
local(sname) = #sname + server_name
local(fruit_before) = string
if(web_request -> param('session') -> asstring == 'start') => {
    session_start(-name=#sname, -expires=15, -cookieexpires=15, -usecookie, -useauto=false)
    var(fruit) = map
    session_addvar(-name=#sname,'fruit')

else(web_request -> param('fruit') -> asstring -> size)
    session_start(-name=#sname, -expires=15, -cookieexpires=15, -usecookie)
    #fruit_before = 'before: ' + (var_defined('fruit') ? $fruit)
    $fruit -> insert(date -> format('%q') = web_request -> param('fruit') -> asstring)

else(web_request -> param('session') -> asstring == 'end')
    session_start(-name=#sname, -expires=-999999, -cookieexpires=-999999)
    session_end(-name=#sname)
    var(fruit) = map
    redirect_url(response_filepath)
}
]
<pre>[var('__http_header__')]</pre>
[if(!session_id(-name=#sname) -> asstring -> size) => {^]
    <p><a href="?session=start">start/load session</a></p>
[else]
    <p><a href="?session=end">end session</a></p>
    <h3>Add a fruit to your session.</h3>
    <ul>
    [with i in array('Santa Rosa plum', 'Gala apple', 'Meyer lemon') do => {^]
       <li><a href="?fruit=[#i]">[#i]</a></li>
    [^}]
    </ul>
[^}]

<h3>Session ID</h3>
<p>[session_id(-name=#sname)]</p>
<h3>Session Fruits</h3>
<p>[#fruit_before]</p>
<p>[var_defined('fruit') ? $fruit]</p>
<h3>Cookies</h3>
<p>
[with c in web_request -> cookies do => {^
    #c + '<br>'
^}]
</p>