Solid Möbius strip with POV-Ray

.gitignore

*.png
*.ini

SolidMobiusStrip.pov

#version 3.7;

global_settings { assumed_gamma 2 radiosity { normal on }}
 

#include "colors.inc"
#include "textures.inc"

// ---- SCENE ------------------------------------------------------------------
// camera 
camera {
    angle     75
    location  <0, 2, -12>
    right     x*image_width/image_height
    look_at   <0, 2, 0>
}
// light sources, sun
light_source { 
    <1500,5000,-2500> color White 
}
light_source { 
    <-1600, 1300, 3000> color Black
    looks_like { 
        sphere {
            0, 100
            pigment { 
                rgbt 1 
            } 
            hollow
            interior { 
                media { 
                    emission 1
                    density { 
                        spherical density_map { 
                            [0 rgb 0]
                            [60 Orange]
                            [80 Red]
                            [100 Yellow]
                        }
                        scale 100
                    }
                }
            }
            scale 4
        }
    }
} 
// sky with clouds
plane { 
    <0,1,0>,1 hollow  
    texture{
        pigment { 
            Bright_Blue_Sky
            scale 3
        }
        finish { 
            emission 0.5 
            diffuse 0 
        } 
    }      
    scale 10000
}
// fog
fog { 
    fog_type   2
    distance   50
    color      White
    fog_offset 0.1
    fog_alt    2.0
    turbulence 0.8
}
// sea 
plane { <0,1,0>, 0 hollow
    texture{
        pigment{
            rgb <.2,.2,.2>
        }
        finish {
            ambient 0.15
            diffuse 0.55
            brilliance 6.0
            phong 0.8
            phong_size 120
            reflection 0.4
        }
        normal { 
            bumps 0.75
            turbulence .05 
            scale <1,0.25,1> 
        }
    }
}


// SOLID MOBIUS STRIP  ---------------------------------------------------------
polynomial {8
    xyz(4, 0, 2):  0.04275,
    xyz(5, 1, 1):  0.72,
    xyz(4, 2, 0): -0.53775,
    xyz(8, 0, 0):  0.2025,
    xyz(2, 2, 0):  0.0235125,
    xyz(1, 5, 1):  0.08,
    xyz(2, 4, 2): -0.185,
    xyz(4, 2, 2): -0.185,
    xyz(1, 3, 3): -0.72,
    xyz(2, 2, 2):  1.0275,
    xyz(0, 6, 2):  0.045,
    xyz(2, 4, 0): -0.11975,
    xyz(6, 2, 0):  0.45,
    xyz(0, 4, 2):  0.02475,
    xyz(4, 0, 0):  0.1827563,
    xyz(2, 2, 4):  0.045,
    xyz(0, 4, 0):  0.00075625,
    xyz(4, 0, 4):  0.0025,
    xyz(0, 6, 0): -0.00725,
    xyz(0, 4, 4):  0.2025,
    xyz(6, 0, 2):  0.045,
    xyz(0, 8, 0):  0.0025,
    xyz(2, 6, 0):  0.05,
    xyz(3, 1, 1): -0.684,
    xyz(3, 3, 1):  0.8,
    xyz(1, 3, 1): -0.044,
    xyz(6, 0, 0): -0.42525,
    xyz(3, 1, 3): -0.08,
    xyz(4, 4, 0):  0.295
    texture { 
      pigment{color rgb <0.5, 0, 0>}
      finish {
        irid { 
            0.25 
            thickness 0.6
        }
        brilliance 1
        metallic
        specular 3 
        phong 0.9
        phong_size 60
      }
    }
    rotate <0, 0, 2*frame_number>
    rotate <60, 0, 0>
    scale 3
    translate <0, 3.75, 0>
}

/*
ini file
Antialias = On
Antialias_Threshold = 0.3
Antialias_Depth = 3
Input_File_Name = SolidMobiusStrip.pov
Height = 512
Width = 512
Initial_Frame = 0
Final_Frame = 179
Cyclic_Animation = on
*/ 

SolidMobiusStrip_ab.pov

SolidMobiusStrip_POV.gif