Skip to content

Instantly share code, notes, and snippets.

@synthead synthead/PKGBUILD

Created Mar 9, 2016
Embed
What would you like to do?
# Maintainer: Thomas Dziedzic <gostrc@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Jeramy Rutley <jrutley@gmail.com>
pkgname=(ruby-svn ruby-docs-svn)
pkgver=54049M
pkgrel=1
arch=(i686 x86_64)
url='http://www.ruby-lang.org/en/'
license=(BSD custom)
makedepends=(gdbm openssl libffi doxygen graphviz libyaml ttf-dejavu tk)
options=(!emptydirs)
source=('ruby::svn+http://svn.ruby-lang.org/repos/ruby/trunk'
gemrc)
sha1sums=('SKIP'
'dc536754c8fac2c3d82965c5a708cd8f79562d98')
pkgver(){
cd ruby
svnversion
}
build() {
cd ruby
autoconf
PKG_CONFIG=/usr/bin/pkg-config ./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sharedstatedir=/var/lib \
--libexecdir=/usr/lib/ruby \
--enable-shared \
--disable-rpath \
--with-dbm-type=gdbm_compat
make
}
check() {
cd ruby
make test
}
package_ruby-svn() {
pkgdesc='An object-oriented language for quick and easy programming'
depends=(gdbm openssl libffi libyaml gmp zlib)
optdepends=(
'ruby-docs: Ruby documentation'
'tk: for Ruby/TK'
)
provides=(ruby rubygems rake)
conflicts=(ruby rake)
backup=(etc/gemrc)
install=ruby.install
cd ruby
make DESTDIR="${pkgdir}" install-nodoc
install -D -m644 ${srcdir}/gemrc "${pkgdir}/etc/gemrc"
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/ruby/LICENSE"
install -D -m644 BSDL "${pkgdir}/usr/share/licenses/ruby/BSDL"
}
package_ruby-docs-svn() {
pkgdesc='Documentation files for ruby'
provides=(ruby-docs)
conflicts=(ruby-docs)
cd ruby
make DESTDIR="${pkgdir}" install-doc install-capi
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/ruby-docs/LICENSE"
install -D -m644 BSDL "${pkgdir}/usr/share/licenses/ruby-docs/BSDL"
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.