hydrogen-helpers

init.coffee

hydrogenAppendCell = (editor) ->
  scope = editor.getLastCursor().getScopeDescriptor()
  {commentStartString} = editor.getCommentStrings(scope)
  [startRow, endRow] = editor.getLastSelection().getBufferRowRange()

  pattern = ///\s*#{commentStartString}\s*%%\s*$///

  for row in [startRow..endRow]
    scanRange = editor.bufferRangeForBufferRow(row)
    replaced = false
    editor.scanInBufferRange pattern, scanRange, ({range, replace}) ->
      unless range.isEmpty()
        replace('')
        replaced = true

    unless replaced
      point = [row, Infinity]
      editor.setTextInBufferRange([point, point], " #{commentStartString}%%")

hydrogenRestartKernelAndRunAll = (editorElement) ->
  atom.commands.dispatch(editorElement, 'hydrogen:restart-kernel')
  setTimeout ->
    atom.commands.dispatch(editorElement, 'hydrogen:run-all')
  , 1000


atom.commands.add "atom-text-editor:not([mini])",
  "user:hydrogen-append-cell": ->
    hydrogenAppendCell(@getModel())
  "user:hydrogen-restart-kernel-and-run-all": ->
    hydrogenRestartKernelAndRunAll(this)

keymap.cson

'atom-workspace:not([mini])':
  'cmd-m': 'user:hydrogen-append-cell'
  'cmd-h': 'user:hydrogen-restart-kernel-and-run-all'