Gradle setup for elasticsearch >= 5.x plugin dependencies

build.gradle

apply plugin: "java"

repositories {
    mavenCentral()
    ivy {
        url "https://artifacts.elastic.co/downloads/elasticsearch-plugins/"
        layout 'pattern', {
//            https://artifacts.elastic.co/downloads/elasticsearch-plugins/analysis-phonetic/analysis-phonetic-5.4.0.zip
            artifact '/[module]/[module]-[revision].[ext]'
        }
    }
}

configurations {
    zipped
}

task installDependencies(type: Sync) {
    def extractDir = "${buildDir}/my-libs"

    ext.extractedJars = fileTree(extractDir) {
        include "**/*.jar"
        builtBy "installDependencies"
    }

    dependsOn configurations.zipped
    from {
        configurations.zipped.collect { zipTree(it) }
    }
    into extractDir
}

dependencies {
    compile "org.elasticsearch:elasticsearch:5.4.0"
    zipped "org.elasticsearch.plugin:analysis-phonetic:5.4.0@zip"
    compile files({ tasks.installDependencies.extractedJars })
}

It works, but you don't get sources. And I reckon it'll cause jar-hell if anything else happens to pull in dependencies provided in the plugin zip.