Functional Lenses and Groovy

lenstest.groovy

import groovy.transform.*

// Immutable test object
def tim = new Person( 'tim', new Address( 'Woo', 123 ) )

// Lens for setting address for a person
Lens personAddress  = new Lens( { p -> p.address }, { p, a -> new Person( p.name, a ) } )

// And one for setting zipcode for an address
Lens addressZipcode = new Lens( { a -> a.zip },     { a, z -> new Address( a.street, z ) } )

// Compose them into one for setting zipcode for a person
Lens personZipcode = addressZipcode << personAddress

// Simplistic test
assert personZipcode( tim, 100 ) == new Person( 'tim', new Address( 'Woo', 100 ) )

//////////////////////////////////
// Test classes

@Immutable
class Address {
    String street
    Integer zip
}

@Immutable
class Person {
    String name
    Address address
}

//////////////////////////////////
// Lens implementation

@Immutable
class Lens {
    Closure getter
    Closure setter

    def call( a    ) { getter( a    ) }
    def call( a, b ) { setter( a, b ) }

    Lens leftShift( Lens other ) { 
        new Lens( { a    -> get( other.getter( a ) ) },
                  { a, b -> other.setter( a, setter( other.getter( a ), b ) ) } )
    }
}

Maybe simpler with copyWith() ?

http://mrhaki.blogspot.fr/2013/11/groovy-goodness-create-copywith-method.html

// Lens for setting address for a person
Lens personAddress = new Lens( { p -> p.address }, { p, a -> p.copyWith(address: a) } )

// And one for setting zipcode for an address
Lens addressZipcode = new Lens( { a -> a.zip }, { a, z -> a.copyWith(zip: z) } )

@Immutable(copyWith = true)
class Person {
...
}