Manages character counts for a textarea

jquery.textcounter.js.coffee

# Usage
$("textarea").counter
  elements:
    counter: '.note-area p.counter'

# Manages Character Counts
jQuery.fn.counter = (opts) ->
  defaults =
    elements:
      counter:  '.counter'
    css:
      warning:  'warning'
      exceeded: 'exceeded'
    limits:
      allowed:  300
      warning:  75
    copy:
      prepend:  ''
      append:   ' characters remaining'

  opts = $.extend defaults, opts

  opts.elements.textarea = $ this
  opts.elements.counter  = $ opts.elements.counter

  update = ->
    used    = opts.elements.textarea.val().length
    remain  = opts.limits.allowed - used

    if remain <= opts.limits.warning and remain >= 0
      opts.elements.counter.addClass opts.css.warning
    else
      opts.elements.counter.removeClass opts.css.warning

    if remain < 0
      opts.elements.counter.addClass opts.css.exceeded
    else
      opts.elements.counter.removeClass opts.css.exceeded

    opts.elements.counter.html "#{opts.copy.prepend}#{remain}#{opts.copy.append}"

  this.keyup  -> update()
  this.change -> update()