Applies func(s) to elements of series

each.red

Red [
	Description: {Applies function or sequence of functions 
		to block or collected output of previous functions}
	Date: 18-May-2019
	Author: "Toomas Vooglaid"
]
each*: make op! function [fn [any-function! block!] block [series!]][
	{Applies a function to as many elements of the block as it has arguments
	or a sequence of functions to the block or collected output of the previous function.
	Returns block with the collected result of last function}
    append fns: clear [] reduce :fn 
    foreach fn fns [
        words: parse spec-of :fn [collect [
            some [refinement! break | keep word! | skip]]
        ] 
        code: compose/deep [
            block: collect [
                foreach [(words)] block [
                    attempt [keep (compose either op? :fn [
                        [(words/1) fn (words/2)]
                    ] [
                        [fn (words)]
                    ])]
                ]
            ]
        ] 
        do code
    ]
]
;Simple `each`
each: make op! func [fn block][forall block [fn block/1]]