Nifi Expression Language Testing from the command-line for 1.12.1

testel.groovy

// eg. groovy testEL.groovy -D filename=hello '${filename:append("_world")}'
@Grab(group='org.apache.nifi', module='nifi-expression-language', version='1.12.1')
import org.apache.nifi.attribute.expression.language.*

def cli = new CliBuilder(usage:'groovy testEL.groovy [options] [expressions]',
                          header:'Options:')
cli.help('print this message')
cli.D(args:2, valueSeparator:'=', argName:'attribute=value',
       'set value for given attribute')
def options = cli.parse(args)
if(!options.arguments()) {
  cli.usage()
  return 1
}

def attrMap = [:]
def currKey = null
options.Ds?.eachWithIndex {o,i ->
  if(i%2==0) {
    currKey = o
  } else {
    attrMap[currKey] = o
  }
}
options.arguments()?.each {
  def q = Query.compile(it)
  def sec = new StandardEvaluationContext(attrMap ?: null)
  println q.evaluate(sec)
}

Based on the work of mburgess @ https://community.cloudera.com/t5/Community-Articles/Testing-NiFi-Expression-Language-with-Groovy/ta-p/247208

I had to add import groovy.cli.commons.CliBuilder otherwise I was getting unable to resolve class CliBuilder error.