https://www.reddit.com/r/dailyprogrammer/comments/n94io8/20210510_challenge_389_easy_the_monty_hall_problem/

monty hall.hs

import System.Random
import Data.List
import Control.Monad

type StepTwoChoice = IO Int

type StepFourChoice = Int -> IO Bool

data Stratergy = Stratergy
  { setpTwo :: StepTwoChoice,
    stepFour :: StepFourChoice
  }

simulationAmount :: Num n => n
simulationAmount = 1000

alice :: Stratergy
alice = Stratergy (return 1) (const (return False))

bob :: Stratergy
bob = Stratergy (return 1) (const (return True))

carol :: Stratergy
carol = Stratergy (randomRIO (1, 3)) randomBool
    where randomBool _ = toEnum <$> randomRIO (0, 1)

dave :: Stratergy
dave = Stratergy (randomRIO (1, 3)) (const (return False))

erin :: Stratergy
erin = Stratergy (randomRIO (1, 3)) (const (return True))

frank :: Stratergy
frank = Stratergy (return 1) fourth
    where fourth a = return $ a == 2

pickStillClosedDoor :: Int -> Int -> IO Int
pickStillClosedDoor winning_door picked_door = 
    if winning_door == picked_door
    then do
        index <- randomRIO (0, 1)
        return $ remaining !! index
    else return winning_door
    where remaining = [door | door <- [1,2,3], door /= picked_door]

game :: Stratergy -> IO Bool
game (Stratergy first second) = do
    winning_door <-  randomRIO (1, 3)
    first_choice <- first
    closedDoor <- pickStillClosedDoor winning_door first_choice
    swap <- second closedDoor
    let final_choice = if swap then closedDoor else first_choice

    return $ final_choice == winning_door

boolToFloat :: Bool -> Float
boolToFloat True = 1
boolToFloat False = 0

simulate :: Stratergy -> IO Float
simulate strat = do
    games <- replicateM simulationAmount $ game strat
    let won = sum $ map boolToFloat games
    return $ won / simulationAmount

strats = [
     ("alice", alice)
    ,("bob", bob)
    ,("carol", carol)
    ,("dave", dave)
    ,("erin", erin)
    ,("frank", frank)
    ]

main = do
    forM_ strats $ \(name, strat) -> do
        result <- simulate strat
        let prosent = round $ result * 100
        putStrLn $ name ++ " won " ++ show prosent ++ "%"